pro extended_maps,mem=mem,clean=clean,cm,pixel,date=date,energy=energy,det=det,$
	dur=dur,roll=roll,units=units,soho=soho,help=help
	
if keyword_set(help) then begin
	print,'PURPOSE:'
	print,'	Produce PostScript plots for extended RHESSI sources using'
	print,'	MEM_NJIT, Clean, and plot_map'
	print,'HELP:'
	print,'	pro extended_maps,mem=mem,clean=clean,cm,pixel,date=date,'
	print,'		energy=energy,det=det,dur=dur,roll=roll,units=units,'
	print,'		soho=soho'
	print,'	inputs:	mem (mem data, float array, i.e. image.map)'
	print,'		clean (clean data from image object, float array)'
	print,'		cm (center of the map, 2 element float array)'
	print,'		pixel (pixel size in arcsec, float)'
	print,'		date (date and time of flare, string, required keyword)'
	print,'		energy (energy string, i.e. "6.0 - 12.0 keV", required)'
	print,'		 *energy must be in the same format as the above example*
	print,'		det (detectors used, 2 element float array, required)'
	print,'		 *detectors need to be zero offset*'
	print,'		FOR USE IN PLOT_MAP (also uses cm and pixel)'
	print,'		IF NOT ASSIGNED A VALUE, DEFAULT IS USED'
	print,'		dur (desired duration of flare, string)'
	print,'		roll (roll angle, float)'
	print,'		units (units of map, string)'
	print,'		soho (???, byte)'
	print,'	outputs:4 PostScript files (unique)'
	print,'AUTHOR:'
	print,'	Rick Pernak, Goddard Space Flight Center'
	return
endif

loadct,5

;create structure for plot_map
default,units,'arcsec'
default,soho,0B
default,dur,''
default,roll,0.

xc = cm[0]
yc = cm[1]
dx = pixel
dy = pixel

;configure date for filename
date_split = strsplit(date,/extract,escape=',')
month = date_split[0]
day = (strsplit(date_split[1],/extract))[0]
year = (strsplit(date,/extract))[2]
start = date_split[2] ;starting time

;choose month abbreviation, to be used in file name
month = strlowcase(strmid(month,0,3))
time = day+'-'+month+'-'+year+' '+start ;time for plot_map

;abbreviate energy string, to be used in the file name
en1 = (strsplit(energy,/extract))[0]
en2 = (strsplit(energy,/extract))[2]
en1 = strcompress(fix(en1),/rem) ;make "integer strings"
en2 = strcompress(fix(en2),/rem)

;make uv/sc string for legend
new_det = det + 1.
tot_det = new_det[1] - new_det[0] + 1
detectors = indgen(tot_det) + new_det[0]
uv_leg = string(detectors,format='("UV Circles",1x,i1,1x,i1,1x,i1,1x,i1,1x,i1,1x,i1,1x,i1,1x,i1,1x,i1)')
sc_leg = string(detectors,format='("Detectors",1x,i1,1x,i1,1x,i1,1x,i1,1x,i1,1x,i1,1x,i1,1x,i1,1x,i1)')

;make uv/sc string for file name
uv1 = strcompress(fix(new_det[0]),/rem)
uv2 = strcompress(fix(new_det[1]),/rem)
circles = uv1+'-'+uv2

if keyword_set(mem) then begin
	;Create MEM maps
	data = mem
	struct = {data:data,xc:xc,yc:yc,dx:dx,dy:dy,roll_angle:roll,dur:dur,time:time,$
		xunits:units,yunits:units,soho:soho}

	;make MEM image
	name = month+day+'img_'+en1+'-'+en2+'_uv'+circles+'.ps'
	set_plot,'ps'
	device,filename=name,xsize=16,ysize=16,/color
	plot_map,struct,/notitle,/limb,lmcolor=255,lmthick=3
	legend,[date,uv_leg,energy],box=0,textcolors=255
	device,/close

	;MEM contour map
	name = month+day+'con_'+en1+'-'+en2+'_uv'+circles+'.ps'

	set_plot,'ps'
	device,filename=name,xsize=16,ysize=16,/color
	plot_map,struct,/notitle,/cont
	legend,[date,uv_leg,energy],box=0
	device,/close
	set_plot,'x'
endif

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
if keyword_set(clean) then begin
	;Create Clean maps


	;Clean image

	data = clean
	struct = {data:data,xc:xc,yc:yc,dx:dx,dy:dy,roll_angle:roll,dur:dur,time:time,$
		xunits:units,yunits:units,soho:soho}

	set_plot,'ps'
	name = month+day+'img_'+en1+'-'+en2+'_sc'+circles+'.ps'
	device,filename=name,xsize=16,ysize=16,/color
	plot_map,struct,/notitle,/limb,lmcolor=255,lmthick=3
	legend,[date,sc_leg,energy],box=0,textcolors=255
	device,/close

	;Clean contour map
	;name = datef+'con_'+energyf+'_sc'+circlesf+'.ps'

	set_plot,'ps'
	name = month+day+'con_'+en1+'-'+en2+'_sc'+circles+'.ps'
	device,filename=name,xsize=16,ysize=16,/color
	plot_map,struct,/notitle,/cont
	legend,[date,sc_leg,energy],box=0
	device,/close

	set_plot,'x'
endif

return
end