pro make_vis_plot,image,isc_start,isc_end,flux,pixel_size,xyoffset,mem_data

; PURPOSE
;		Makes a plot from the RHESSI visibility data and MEM_NJIT result.
;
;	INPUTS
;		image = output from MEM NJIT (should be 128x128 array taken from 'image' structure)
;		isc_start = starting collimator/uv circle
;		isc_end = ending collimator/uv circle
;		flux = flux parameter used in MEM NJIT
;		pixel_size = spatial scale (from MEM NJIT), in units arcsec/pixel
;		xyoffset = xy offset of source, obtained from HEDC site, an array [x,y]
;
;	OUTPUTS
;		mem_data = structure of MEM NJIT parameters
;			pixel_size: see pixel_size above
;			xr: xrange
;			yr: yrange
;			xyoffset: see xyoffset above
;
; CALLING EXAMPLE
;		User should run MEM_NJIT first, which requires calculating u,v, and vis 
;		arrays, which requires a user-inputted starting collimator (isc_start,e.g. 3)
;		and ending collimator (isc_end,e.g. 7). Then:
;		make_vis_plot,image,3,7,2,[-895,-226],params
;
;		mem_map.pro automatically calls this program, so isc_start, isc_end, image, 
;		pixel_size and xyoffset are passed here.
;	
;	Rick Pernak, Goddard Space Flight Center

window,xsize=600,ysize=600

;generate graph labels/legend data
xt = 'Heliocentric X (arcsec)'
yt = 'Heliocentric Y (arcsec)'

day = ''
read,day,prompt='Please enter date (dd-mmm-yyyy): '

start_t = ''
read,start_t,prompt='Starting time (tt:tt:tt.ttt)? '

end_t = ''
read,end_t,prompt='Ending time (tt:tt:tt.ttt)? '

date = string(day," ",start_t," to ",end_t)

read,e1,e2,prompt='What is the energy range (e1,e2 in keV)? '
en = string(e1,e2,format='("Energy Range: ",f5.1,1x,"-",1x,f5.1,1x,"keV")')

total = isc_end - isc_start + 1 ;total number of uv circles
circles = indgen(total) + (isc_start + 1) ;for zero offset
uv = string(circles,format='("UV Circles",1x,i1,1x,i1,1x,i1,1x,i1,1x,i1,1x,i1,1x,i1)')

mem = string(flux,format='("MEM NJIT Total Flux =",1x,f7.1,1x,"photons/cm^2/s")')

x = xyoffset[0] + (indgen(128) - 64) * pixel_size
y = xyoffset[1] + (indgen(128) - 64) * pixel_size
xr = [min(x),max(x)]
yr = [min(y),max(y)]

;make map
lev = [.1,.2,.3,.4,.5,.6,.7,.8,.9,1.]
contour,image,x,y,xtitle=xt,ytitle=yt,/iso,/xst,/yst,title='RHESSI Visibility Image',charsize = 1.5,levels = lev * max(image)
legend,[date,en,uv,mem],box=0,charsize = 1.25

mem_data = {pixel_size:pixel_size,xr:x,yr:y,xyoffset:xyoffset}
return
end