function vis_examples,n

example=[{obs:'2002-mar-25 ' + ['20:06:10', '20:06:14'],xy: [-281, 247],com:' March 25 2002 example--compact - used for phase cal'},$
         {obs:'2002-mar-25 ' + ['20:06:10', '20:08:10'],xy: [-281, 247],com:' March 25  2002 example--compact - used for phase cal'},$
         {obs:'2002-jul-23 ' + ['00:30:00', '00:31:20'],xy: [-885,-233],com:' July 23 example  -- per EJS email 8-4-04, (modamp>1)  '},$
         {obs:'2002-aug-28 ' + ['18:57:50', '18:58:50'],xy: [-939, 166],com:' Aug 28,2002 example  -- per ejs email 3-16-05    '},$
; xy is obsolete         {obs:'2002-aug-28 ' + ['18:57:50', '18:58:50'],xy: [-963, 168],com:' Aug 28,2002 example  -- per ejs email 3-16-05    '},$
         {obs:'2002-apr-21 ' + ['02:10:00', '02:10:30'],xy: [ 985,-268],com:' April 21, 2002 example                           '},$
         {obs:'2002-apr-21 ' + ['01:31:00', '01:31:40'],xy: [ 957,-259],com:' the "BRD" interval                               '},$
         {obs:'2002-feb-20 ' + ['09:57:00', '09:58:30'],xy: [ 925, 295],com:' Feb 20 example                                  '},$
         {obs:'2002-feb-20 ' + ['21:05:30', '21:06:30'],xy: [ 170,-190],com:' Feb 20 2106 example                             '},$
         {obs:'2002-feb-20 ' + ['11:06:00', '11:07:00'],xy: [ 906, 261],com:' Feb 20 1106 example (Sams flare, 1 asec pxls)  '}, $
         {obs:'2002-apr-20 ' + ['23:25:39', '23:27:30'],xy: [930, -203],com:' Apr 20 - used for phase calib '} ]

if n_elements(n) gt 0 then example=example(n)

return,example

end

PRO VIS_TEST, subcoll, PS=ps, NRB=nrb, NFB=nfb, DPHZ=dphz, HARM=harm, CALIB_OBJ=oce, ENERGY_BAND=energy_band,$
  N_example=N_example
;
; Shell program that calls hsi_visibility_analysis to calculate, display and use visibilities for a hardwired
;	time, energy interval.
;
; subcoll 		= vector of up to 9 elements indicating which subcollimators to use (default= [1,2,3,4,5,6,7,8,9])
; DPHZ 			= phase correction in radians 													(default = 0)
; HARM 			= 1,2 or 3 indicates which harmonic to use 										(default = 1)
; PS 			= 1 sends plotted output to idl.ps 												(default = 0)
; NRB 			= number of roll bins
; NFB 			= number of phase bins
; CALIB_OBJ 	= provides and/or receives the calibrated eventlist object
; ATTEN			= If set, visibility amplitudes are corrected for detector&attenuator response. (default = 0)
; ENERGY_BAND 	= 2-element vector specifying energy range 										(default=[12,25])
;
;  5-Aug-04    	First version with hardwired inputs.  ghurford@ssl.berkeley.edu
;  3-Dec-04 gh 	Add phase, nullamp and visibility plane plots
;          		Add PS keyword
;          		Add DPHZ keyword
; 13-Dec-04 gh  Break out actual analysis into module, hsi_visibility_analysis
; 11-Mar-05 gh  Add HARM keyword
;               Pass subcoll parameter on to hsi_visibility analysis
; 13-Mar-05 rs	Adds CALIB_OBJ keyword
;			gh	Add NRB keyword
; 22-Mar-05 gh	Add NFB keyword
; 19-Apr-05 gh	Add default for subcoll parameter
; 21-Apr-05 EJS Moved examples out into a separate function vis_examples(n)
; 22-Apr-05 gh	Minor cleanup
; 25-Apr-05 gh	Request stacked rate plots
;
oce     = is_class(/quiet, oce,'HSI_CALIB_EVENTLIST') ? oce : hsi_calib_eventlist()

default,	N_example,	1
example				=vis_examples()
obs_time_interval	=example[N_example].obs
xyoffset			=example[N_example].xy

; Define the calibrated eventlist object

default, subcoll, 	[1,2,3,4,5,6,7,8,9]
default, dphz, 		0
default, ps, 		0
default, harm,		1
default, nrb, 		32
default, nfb, 		0
default, atten, 	-1
IF N_ELEMENTS(energy_band) NE 2 THEN energy_band = [12,25]
oce-> set, obs_time_interval  	= obs_time_interval
oce-> set, xyoffset          	= xyoffset
oce-> set, time_range      		= [0,0]                         ; to force use of full obs_time_interval
oce-> set, energy_band   		= energy_band
oce-> set, det_index_mask   	= [1,1,1, 1,1,1, 1,1,1]
;
hsi_visibility_analysis, oce, subcoll, DPHZ=dphz, PS=ps, HARM=harm, NRB=nrb, NFB=nfb, /RATE_PLOT
;
RETURN
END