Kim Tolbert 28 Nov 2012

Creating a plotman object

Plotman Functions

Plotman Procedures

Plotman Colors

Plotman Parameters

Examples

Note: This documentation is not complete. It is a work in progress.

In the following examples, p is the plotman object reference.

p = plotman()

Or when you have an xyplot, utplot, specplot, or map object, just call

xyplot_obj -> plotman

To return the plotman object reference (e.g. to send more plots to same plotman instance):

xyplot_obj -> plotman, plotman_obj=p

Plotman reserves 17 slots at the top end of its stored colortable for discrete colors.  For each panel, plotman stores three 256 element byte arrays - rcolors, gcolors, and bcolors.  The red, green, blue arrays corresponding to the user's choice of colortable are compressed into the first 239 spaces in the rcolors, gcolors, bcolors arrays and the top 17 slots always contain the same discrete colors.  The names and indices of those discrete colors can be retrieved as follows:

c=p->get(/color_names)
IDL> help,c,/st
** Structure PLOTMAN_COLOR_NAMES, 17 tags, length=34, data length=34:
VIOLET  239
LIME  240
BLACK  241
MAROON  242
RED  243
PINK  244
ORANGE  245
YELLOW  246
OLIVE  247
GREEN  248
DKGREEN  249
CYAN  250
BLUE  251
DKBLUE  252
MAGENTA  253
PURPLE  254
WHITE  255

In the GUI, users select the colortable through the Plot Control / Image Display Options widget.  To change colors at the command line, users can either set the colortable number, or set the red, green, and/or blue arrays. In either case, the colors will be compressed to the first 239 space in the stored plotman color table.  e.g.

p->set,colortable=5
or
p->set,red=indgen(256)

To replot a panel with the new colors, a second select must be called before plotting, i.e.

p->select
p->set,colortable=6
p->select
p->plot

Colors:

1. Extract the data object for a panel

   To retrieve the data object stored for the second panel in plotman:

   panels=p->get(/panels) ; returns a linkelist object with panel information
   print,panels->get_count()  ; prints number of panels stored
   p1 = panels->get_item(1) ; gets second panel stored (0 is first)
   saved_data = (*p1).saved_data
   dobj = *saved_data.data

    

2. Using a map object that contains multiple maps with plotman and changing the colors of some of the maps:

   omap=obj_new('map')
   for k=0,3 do omap->setmap,k,make_map(100*randomn(seed)*dist(64),id=string(k))
   
   ;first plot all four objects with color table 3
   loadct,3
   tvlct,r,g,b,/get
   for k=0,3 do omap->plotman,k,plotman=p,red=r,green=g,blue=b
   
   ; now get r,g,b arrays for color table 5, and replace the first and second panels with that color table
   loadct,5
   tvlct,r,g,b,/get
   for k=0,1 do omap->plotman,k,plotman=p,red=r,green=g,blue=b, nodup=0, /replace
   
   ; now get r,g,b arrays for color table 32 and use reset_panel_pc to change the saved colors for the third and fourth panels and replot all 4 panels
   
   loadct,32
   tvlct,r,g,b,/get
   p->reset_panel_pc, {red:r, green:g, blue:b}, panels=[0,0,1,1]
   p->show_panel, /all, nacross=2
   
   ; now use reset_panel_pc to change the saved color table for the second panel 2 to color table 5 and replot all 4 panels
   p->reset_panel_pc, {colortable: 5}, panels=[0,1]
   p->show_panel, /all, nacross=2
    

3. Create a utplot object with two y arrays and errors and plot in plotman:

   ; This part just sets up a 2,10 time array and arrays for y1 and y2 and their corresponding error arrays
   t = anytim('12-sep-2012 10:00') + findgen(12)*10.d
   t=get_edges(t,/edges_2)
   y1=findgen(10) & y2=findgen(10)+2.
   y1_err=fltarr(10) + .5 & y2_err=fltarr(10) + 1.
   
   ; create utplot object using plotman
   
   ut_obj = obj_new('utplot', t, [[y1],[y2]], [[y1_err],[y2_err]])
   ut_obj->set,dim1_ids=['y1 data', 'y2 data'], id='Using utplot object', data_unit='y units'
   ut_obj->plotman,desc='testerr'