;+

; Project     : SOLAR-B - EIS

;

; Name        : EIS_CPT_RESPONSE_STUDY

;

; Purpose     : Returns flag if response study.

;

; Explanation : Returns 1 if response study.

;               Returns 0 if not response study.

;

; Use         : < response_flag = eis_cpt_response_study ( control_details, study_identifier) >

;

; Inputs      : control_details       : STRUCTURE of type EIS_control_details.

;               study_identifier      : ULONG study identifier from planning tools.

;

; Opt. Inputs : None.

;

; Outputs     : response_flag : FLAG indicating response study

;

; Opt. Outputs: None.     :

;

; Keywords    : RESPONSE_STUDY_ID    : ULONG study identifier of response study

;               RESPONSE_DESCRIPTION : STRING study description

;               RESPONSE_RASTER_ID   : ULONG  raster identifier for response raster

;               ADJUST_X             : FLAG indicating adjust x allowed for response

;               ADJUST_Y             : FLAG indicating adjust y allowed for response

;

; Calls       : None.

;

; Common      : None.

;

; Restrictions: None.

;

; Side effects: May output ASCII files.

;

; Category    : EIS_CPT.

;

; Prev. Hist. : None.

;

; Written     : Martin Carter RAL 21/06/06

;

; Modified    : Version 0.0, 21/06/06, MKC

;               Version 0.1, 20/04/07, MKC

;                 Changed processing.

;               Version 0.2, 30/04/13, MKC

;                 Extended use of this routine to include eis cpt response raster.

;                 Changed study id returned to response flag.

;                 Added KEYWORDS RESPONSE STUDY ID, RESPONSE DESCRIPTION, RESPONSE RASTER ID,

;                 ADJUST X, ADJUST Y.

;

; Version     : 0.2, 30/04/13

;-

;**********************************************************



FUNCTION eis_cpt_response_study, control_details, study_identifier, $

                                 RESPONSE_STUDY_ID=response_study_id, $

                                 RESPONSE_DESCRIPTION=response_description, $

                                 RESPONSE_RASTER_ID=response_raster_id, $

                                 ADJUST_X=response_adjust_x, $

                                 ADJUST_Y=response_adjust_y



  ; zero keyword arguments



  response_study_id    = 0



  response_description = ''



  response_raster_id   = 0



  response_adjust_x    = 0



  response_adjust_y    = 0



  ; check if response study else return 0



  IF (study_identifier GE 1) AND (study_identifier LE 4) THEN BEGIN



    ; check if control_details defined



    IF NOT KEYWORD_SET(control_details) THEN MESSAGE, 'IMPLEMENTATION ERROR'



    ; check type of response study



    CASE study_identifier OF



      1 : BEGIN



            ; XRT flare response



            response_study_id    = control_details.XRT_flare_control.response_identifier



            response_description = 'XRT flare response study'



            response_raster_id   = control_details.XRT_flare_control.raster_identifier



            response_adjust_x    = control_details.XRT_flare_control.adjust_X



            response_adjust_y    = control_details.XRT_flare_control.adjust_Y



          END



      2 : BEGIN



            ; XRT filler response



            response_study_id    = control_details.XRT_flare_control.filler_identifier



            response_description = 'XRT filler study'



            response_raster_id   = 0



            response_adjust_x    = 0



            response_adjust_y    = 0



          END



      3 : BEGIN



            ; EIS flare response



            response_study_id    = control_details.EIS_flare_control.response_identifier



            response_description = 'EIS flare response study'



            response_raster_id   = control_details.EIS_flare_control.raster_identifier



            response_adjust_x    = control_details.EIS_flare_control.adjust_X



            response_adjust_y    = control_details.EIS_flare_control.adjust_Y



          END



      4 : BEGIN



            ; EIS event response



            response_study_id    = control_details.EIS_event_control.response_identifier



            response_description = 'EIS event response study'



            response_raster_id   = control_details.EIS_event_control.raster_identifier



            response_adjust_x    = control_details.EIS_event_control.adjust_X



            response_adjust_y    = control_details.EIS_event_control.adjust_Y



          END



      ELSE : MESSAGE, 'IMPLEMENTATION ERROR'



    ENDCASE



    ; flag as response study



    RETURN, 1



  ENDIF ELSE BEGIN



    ; flag as not a response study



    RETURN, 0



  ENDELSE



END