;+
; Project     : SOLAR-B - EIS
;
; Name        : EIS_CPT_OBSTBL_MAP_TEXT
;
; Purpose     : Produces text output for one line of OBSTBL map.
;
; Explanation : Produces text output for one line of OBSTBL map.
;
; Use         : < res = eis_cpt_obstbl_map_text(type, index, used, time, description) >
;
; Inputs      : type        : STRING string giving table type. One of :
;                               'SEQUENCE','LINELIST','AECTABLE','AECEXPOS','XRTFLARE','EISFLARE','EISEVENT'
;               index       : INTARR[] giving each table index
;               used        : INTARR[] flag indicating whether each table used
;               time        : DBLARR[] giving when each table free
;               description : STRARR[] flag giving description of each table
;
; Opt. Inputs : None.
;
; Outputs     : res  : INT flag indicating result
;                        1 : ok
;                        0 : not ok
;
; Opt. Outputs: None.
;
; Keywords    : FORMAT : INT flag indicating should produce format text.
;               LINK   : INT tabel index of linked sequence table
;               FIRST  : INT flag indicating first sequence in study
;               LAST   : INT flag indicating last  sequence in study
;
; Calls       : None.
;
; Common      : None.
;
; Restrictions: None.
;
; Side effects: None.
;
; Category    : EIS_CPT.
;
; Prev. Hist. : None.
;
; Written     : Martin Carter RAL 04/10/05
;
; Modified    : Version 0.0, 04/10/05, MKC
;               Version 0.1, 12/07/06, MKC
;                 Changed MAP file format.
;                 Included follow on sequence and start of study flag.
;                 Added link, first and last keywords.
;               Version 0.2, 16/04/07, MKC
;                 Added eis cpt version.
;
; Version     : 0.2, 16/04/07
;-
;**********************************************************

FUNCTION eis_cpt_obstbl_map_text, type, index, used, time, description, FORMAT=format, LINK=link, FIRST=first, LAST=last

  IF KEYWORD_SET(format) THEN BEGIN

    RETURN, ['; EIS_CPT version '+eis_cpt_version(), $
             ';   TYPE | INDEX | USED | FIRST | LAST | LINK |    CCSDS-TIME LAST USED | DESCRIPTION']

  ENDIF

  IF NOT KEYWORD_SET(link) THEN link = 0

  ; set up first

  IF NOT KEYWORD_SET(first) THEN first = 0

  ; set up last

  IF NOT KEYWORD_SET(last)  THEN last = 0

  ; set up times

  times = REPLICATE('-----------------------',N_ELEMENTS(time))

  list = WHERE(time NE 0, count)

  IF count GT 0 THEN times[list] = anytim2utc(time[list], /CCSDS)

  ; generate text

  text =  STRING(type,  FORMAT='(A8)')  + ' | ' + $
          STRING(index, FORMAT='(I5)')  + ' | ' + $
          STRING(used,  FORMAT='(I4)')  + ' | ' + $
          STRING(first, FORMAT='(I5)')  + ' | ' + $
          STRING(last,  FORMAT='(I4)')  + ' | ' + $
          STRING(link,  FORMAT='(I4)')  + ' | ' + $
          STRING(times, FORMAT='(A23)') + ' | ' + $
          description

  RETURN, text

END