;+
; PROJECT
;           SOLARB EIS
;
; NAME
;           EIS_MK_PLAN_CREATE_RASTERLIST
;
; PURPOSE
;           This function returns a list of raster details
;
; NOTES
;           The
;
; CATEGORY
;           EIS timeline planning
;
; WRITTEN
;           John A Rainne RAL Jun-2006
;
; VERSION
;          v0.1 JAR 4-Apr-2007
;               Changed compression tag to DPCM
;          v0.2 JAR 7-Apr-2007
;               Changed format of x and y_point
;          v0.3 JAR 20-May-2008
;               Changed compression format from JPEG1 -> JPEG98, etc
;          v0.4 JAR 28-May-2008
;               Changed format. Got rid of individual response studies
;
;-
;______________________________________________________________________________
FUNCTION eis_mk_plan_create_rasterlist , tl

tc         = tl.time_component
sc         = tl.science_component
IF (sc.nRasters LT 1) THEN stop
rasterList = STRARR(sc.nRasters)

FOR i = 0 , sc.nRasters - 1 DO BEGIN

    ; Get studyRaster
    sra = sc.studyRasters[i]

    ;
    ; ID  - needs to be in 000001 format
    ;
    idValue = STRING(format='(I06)',sra.ra_ID)
    ;
    ; Compression
    ;
    CASE sra.ra_compression OF
        0    :  comp = 'none'
        1    :  comp = 'DPCM'
        2    :  comp = 'JPEG98'
        3    :  comp = 'JPEG90'
        4    :  comp = 'JPEG75'
        5    :  comp = 'JPEG50'
        6    :  comp = 'JPEG95'
        7    :  comp = 'JPEG92'
        8    :  comp = 'JPEG85'
        9    :  comp = 'JPEG65'
    ENDCASE
    ;
    ; Repeats
    ;
    duration    = sec2dhms(sra.ra_duration/1000./sra.ra_repeats)
    ra_repeats  = STRJOIN([STRCOMPRESS(sra.ra_repeats),'x(' + duration,')'],/SINGLE)
    ;
    ; Duration
    ;
    ra_duration = sec2dhms((sra.ra_duration/1000./sra.ra_repeats) * sra.ra_repeats)
    ;
    ; ASRC
    ;
    CASE sra.asrc_enabled OF
        0    :  asrc = '..'
        1    :  asrc = 'ON'
    ENDCASE

    ;
    ; XRT Flare
    ;
    CASE sra.xrt_flare_props.xrt_flag OF
        0    :  xrtF = ''
        1    :  xrtF = 'XRTFlare'
    ENDCASE
    IF (STRLEN(xrtF) GT 0) THEN triggers = xrtF
    ;
    ; EIS Flare
    ;
    ra_EISFlareOn = sra.eis_flare_props.flare_flag
    ; ra_EISFlareOn is a BYTARR(25) - all
    index = WHERE(ra_EISFlareOn GE 1)
    CASE index[0] OF
        -1    :  eisF = ''
        ELSE  :  eisF = 'EISFlare'
    ENDCASE
    ;
    ; EIS Event
    ;
    ra_EISEventOn = sra.eis_event_props.event_flag
    ; ra_EISEventOn is a BYTARR(25) - all
    index = WHERE(ra_EISEventOn GE 1)
    CASE index[0] OF
        -1     :  eisE = ''
        ELSE   :  eisE = 'BPTrigger'
    ENDCASE
    ;
    ; AEC Event
    ;
    ra_AECEventOn = sra.aec_props.aec_flag
    ; ra_EISEventOn is a BYTARR(25) - all
    index = WHERE(ra_AECEventOn GE 1)
    CASE index[0] OF
        -1     :  aecE = ''
        ELSE   :  aecE = 'AECEvent'
    ENDCASE

    triggers = [xrtF , eisF , eisE , aecE]
    trig_out = ''
    FOR j = 0, 3 DO BEGIN

       IF (STRLEN(triggers[j]) GT 0) THEN trig_out = trig_out + triggers[j] + '/'

    ENDFOR
    ;
    ; Pointing
    ;
    x_point = STRTRIM(STRING(format='(F-10.2)',sra.x_point),2)
    y_point = STRTRIM(STRING(format='(F-10.2)',sra.y_point),2)

;    format        = '(A-8,A-22,A-6,A-16,A-12,A-7,A-8,A-8,A-8,A-8,A-10,A-10)'
    format        = '(A-8,A-22,A-14,A-16,A-12,A-7,A-10,A-10,A-26)'
    rasterList[i] = STRING(format=format,idValue            ,               $
                                         sra.ra_acronym     ,               $
                                         comp               ,               $
                                         ra_repeats         ,               $
                                         ra_duration        ,               $
                                         asrc               ,               $
                                         ;eisE               ,               $
                                         ;eisF               ,               $
                                         ;aecE               ,               $
                                         ;xrtF               ,               $
                                         x_point            ,               $
                                         y_point            ,               $
                                         trig_out)

ENDFOR

RETURN , rasterList

END