;+
;
; Generates complete URLs for access to Mees databases
;

FUNCTION mees_name_format, datatype, date, local=local

;
; INPUT PARAMETERS:
;	datatype = Data name, may include preceding 'MEES_'. Valid names are:
;		IVM_CAL		Imaging Vector Magnetograph inverted
;					instrument matrix
;		IVM_CALVAR	IVM calibration variation with wavelength
;               IVM_DARK        Imaging Vector Magnetograph dark current
;               IVM_FP          Imaging Vector Magnetograph Fabry-Perot
;		IVM_SCAT	Imaging Vector Magnetograph scattered light
;		LOG		Observing log
;		MET		Weather 
;		
;	date = Date of desired file, any standard format.
;
; OPTIONAL INPUT KEYWORDS:
;	local - If set, returns as string array, with
;		[site URL, directory, filename].
;
; RETURNS:
;	URL, string.
;
; HISTORY:
;	Written  September 13, 2000  Barry LaBonte
;
;-


; URL top
urltop = 'http://www.solar.ifa.hawaii.edu/'

; Get date information
; Now
now = STRCOMPRESS( SYSTIME() )
now = STR_SEP( now, ' ' )
nex = ANYTIM( now(2)+'-'+now(1)+'-'+now(4), /EXTERNAL )
nyear = now(4)

; Day to plot
tex = ANYTIM( date, /EXTERNAL )

dd = STRTRIM( STRING( tex(4) ), 2 )
IF( STRLEN(dd) LT 2 ) THEN dd = '0' + dd
mm = STRTRIM( STRING( tex(5) ), 2 )
IF( STRLEN(mm) LT 2 ) THEN mm = '0' + mm
year = STRTRIM( STRING( tex(6) ), 2 )

y2 = STRMID( year, 2, 2 )

doy = STRTRIM( ANYTIM2DOY( tex ), 2 )
doy = doy(0)
IF( STRLEN(doy) EQ 1 ) THEN doy = '00' + doy
IF( STRLEN(doy) EQ 2 ) THEN doy = '0' + doy

; What type of data?
mix = STRPOS( datatype, 'MEES_' )
IF( mix  LT 0 ) THEN type = datatype $
	ELSE type = STRMID( datatype, mix+5, 100 )

CASE type OF

; Imaging Vector Magnetograph inverted instrument matrix
	'IVM_CAL': BEGIN
		dirpath = 'Reference/IVM/calibration/'
                filename = 'ivm_cal_db.' + year
        END

; Imaging Vector Magnetograph calibration variation with wavelength
	'IVM_CALVAR': BEGIN
		dirpath = 'Reference/IVM/calibration/'
		filename = 'ivm_calvar_db'
	END


; Imaging Vector Magnetograph dark current
	'IVM_DARK': BEGIN
		dirpath = 'Reference/IVM/calibration/'
		filename = 'ivm_dark_db.' + year
	END

; Imaging Vector Magnetograph Fabry-Perot
	'IVM_FP': BEGIN
		dirpath = 'Reference/IVM/calibration/'
		filename = 'ivm_flat_db.' + year
	END

; Imaging Vector Magnetograph scattered light
	'IVM_SCAT': BEGIN
		dirpath = 'Reference/IVM/calibration/'
                filename = 'ivm_scat_db.' + year
        END

; Mees Observing log filename
	'LOG': BEGIN
		dirpath = 'Reference/MeesLog/Archive/' + year + '/'
		IF( FIX(year) LT 2000 ) THEN y = y2 ELSE y = year
		filename =  'mlog' + y + '.' + mm + '.' + dd
	END

; Mees Meteorology filename
	'MET': BEGIN
		dirpath = 'Weather/Archive/' + year + '/'
		IF( FIX(year) LT 2000 ) THEN y = y2 ELSE y = year
		filename = 'uh' + y + doy + 'e.dat.gz'
	END

ENDCASE

IF( KEYWORD_SET(local) ) THEN result = [urltop, dirpath, filename ] $
		ELSE result = urltop + dirpath + filename

RETURN, result
END