PRO MTMTUNE,IMAGE,M1,M2,TRANS 
; Analyzes 2 10-step tunings of M1 & M2 to find central 
;    wavelengths and peak transmission 
; IMAGE is data array from mtmtune.src, dimensioned (NX,NY,29) 
; Does dark current subtraction & numbercrunching 
; No file input or output, only diagnostic displays 
; TDT  1/16/94 
 
FSR1 = 200.  &  FSR2 = 400. 
DIM = SIZE(IMAGE) 
NX = DIM(1) 
NY = DIM(2) 
N  = DIM(3) 
NP = FLOAT(NX)*NY 
IF (N NE 29) THEN BEGIN  
        PRINT,'Missing images, only ',N,' found' 
        RETURN 
        ENDIF 
 
DARK = (IMAGE(*,*,1) + IMAGE(*,*,23))/2 
FOR I=0,28 DO IMAGE(*,*,I)=IMAGE(*,*,I)-DARK 
FOR I=1,22,21 DO IMAGE(*,*,I)=IMAGE(*,*,I)+DARK 
ANGLE = FINDGEN(10)/9.*360.-180. 
MM1 = FLTARR(10)    &  MM2=MM1 
FOR I= 2,11 DO MM1(I- 2) = TOTAL(IMAGE(*,*,I))/NP
FOR I=12,21 DO MM2(I-12) = TOTAL(IMAGE(*,*,I))/NP
 PLOT,ANGLE,MM1,LINE=0  & WAIT,1
OPLOT,ANGLE,MM2,LINE=1 &  WAIT,1
; Fringing spatial frequencies set by trial & error
;FRINGE = [NX/2.,NY/2.]  &  FWHM = 1.
FRINGE = [NX-16.,4.]   &  FWHM = 12.  

SINFIT,ANGLE,IMAGE(*,*, 2:11),PHAS1,AMP1,OFFSET1,RAD,FRINGE,FWHM 
SINFIT,ANGLE,IMAGE(*,*,12:21),PHAS2,AMP2,OFFSET2,RAD,FRINGE,FWHM 
PRINT,'Mean Phase, Amplitude, Offset for M1, M2:' 
PRINT,TOTAL(PHAS1)/NP,TOTAL(AMP1)/NP,TOTAL(OFFSET1)/NP 
PRINT,TOTAL(PHAS2)/NP,TOTAL(AMP2)/NP,TOTAL(OFFSET2)/NP 
M1 = (PHAS1+180.)*FSR1/360. 
M2 = (PHAS2+180.)*FSR2/360.
S1 = OFFSET1 - AMP1*COS((-180.-PHAS1)/!RADEG)
PHAS1 = 0
S2 = OFFSET2 - AMP2*COS((-180.-PHAS2)/!RADEG)
PHAS2 = 0
TRANS = (AMP1+OFFSET1)*(AMP2+OFFSET2)/((S1+S2)/2.) 
PRINT,'Origin from M1, M2 scans, Mean Peak Transmission'
PRINT,TOTAL(S1)/NP,TOTAL(S2)/NP,TOTAL(TRANS)/NP
RETURN 
END