pro plots2, x, y, dev=dev, color=color, thick=thick, continue=continue, $
		psym=psym, symsize=symsize, linestyle=linestyle
;+
;NAME:
;	plots2
;PURPOSE:
;	Using the "TV2" suite of routines to handle switching
;	between device coordinates and postscript.  PLOTS2 does
;	plotting
;SAMPLE CALLING SEQUENCE:
;	plots2, x, y
;HISTORY:
;	Written 1995 by M.Morrison
;	 8-Jan-97 (MDM) - Added linestyle
;			- Added documentation header
;-
;
common tv2_blk, xsiz_pix, ysiz_pix, xsiz_inch, ysiz_inch, ppinch
;
if (n_elements(color) eq 0) then color = 255
if (n_elements(continue) eq 0) then continue = 0
if (n_elements(thick) eq 0) then thick = 1
if (n_elements(psym) eq 0) then psym = !psym
if (n_elements(symsize) eq 0) then symsize = 1
if (n_elements(linestyle) eq 0) then linestyle = 0
;
if (!d.name ne 'PS') then begin
    plots, x, y, dev=dev, color=color, thick=thick, continue=continue, psym=psym, symsize=symsize, linestyle=linestyle
end else begin
    xx = x / float(xsiz_pix) * !d.x_size
    yy = y / float(ysiz_pix) * !d.y_size
    plots, xx, yy, /dev, color=color, thick=thick, continue=continue, psym=psym, symsize=symsize, linestyle=linestyle
end
;
end