;+
; NAME:
;	SMEI_SEQUENCE::SET_ZOOM
;
;
; PURPOSE:
;	To set the zoom factor for showing a smei sequence.
;
;
; CATEGORY:
;	SMEI_SEQUENCE
;
;
; CALLING SEQUENCE:
;	seqref -> set_zoom, factor
;
;
; INPUTS:
;	factor	int	The factor by which to scale the images.
;			The for reductions, use the inverse key. (0 is
;			the same as 1)
;
;
; KEYWORD PARAMETERS:
;	/inverse	If set, then the factor is a reduction.
;	smooth		Controls whether smoothing will be done on
;			rebinning the image (Note this is only
;			applicable to zoom-in).
;
;
; MODIFICATION HISTORY:
;	Original: 28/7/03; SJT
;-

pro smei_sequence::set_zoom, factor, inverse = inverse, smooth = smooth

if n_params() eq 1 then begin
    if keyword_set(inverse) then self.options.zoom_factor = -factor $
    else self.options.zoom_factor = factor
    if self -> get_pixmap() ne -1 then begin
        self -> mk_pixmap, /destroy
        self -> mk_pixmap
    endif
endif

if n_elements(smooth) ne 0 then begin
    self.options.zoom_smooth = keyword_set(smooth)
    self -> mk_pixmap, /clear
endif

end