;+
; Project     : SOHO - CDS     
;                   
; Name        : SEL_TSENS_MENU
;               
; Purpose     : Selects temperature parameter to be plotted.
;               
; Explanation : Creates the widgets which form the window within which
;               the temperature parameters can be selected.
;               
; Use         : Only within PLOT_CDS_TEMP package.
;    
; Inputs      : None
;               
; Opt. Inputs : None
;               
; Outputs     : None
;               
; Opt. Outputs: None
;               
; Keywords    : None
;
; Calls       : None
;               
; Restrictions: None
;               
; Side effects: None
;               
; Category    : Telemetry
;               
; Prev. Hist. : None
;
; Written     : C D Pike, RAL, 27-Oct-95
;               
; Modified    : 
;
; Version     : Version 1, 27-Oct-95
;-            

PRO sel_tsens_menu

;
;  commons for communication
;
@cds_temperature.com


;
;  guard against trigger happy users
;
if xregistered('sel_tsens') then begin
   widget_control,msg_widg,set_val='One click will do thanks!',/append
   return
endif

;
;  create main base
;
sel_tplot_base = WIDGET_BASE(title='Temperature parameter selection',$
                           /FRAME, /COLUMN, xsize=450,xoffset=575,$
                           group_leader = main_base)

;
;  and subsidiary ones
;
pmenu_base  = WIDGET_BASE(sel_tplot_base, /COLUMN)
m1_widg    = WIDGET_BASE(pmenu_base, /ROW)


;
;  form the widgets
;
;
;  set up font
;
font = "-adobe-helvetica-bold-r-normal--14-100-100-100-p-82-iso8859-1"
;
;  first the 'Done' button to exit and plot
;
doneid = widget_button(m1_widg, value='Exit and Plot', uvalue='Done', font=font)

;
;  then the clear 
;
clearid = widget_button(m1_widg, value='Reset parameter choice', $
                        uvalue='Reset', font=font)

;
;  then the clear and exit
;
cancelid = widget_button(m1_widg, value='Cancel', uvalue='Cancel', font=font)


;
;  and the list widget to display the list
;
plot_tlist_id = widget_list(pmenu_base, value=full_names,ysize=50)


;
;  list of sensors to be plotted
;
tplot_parms = strarr(48)




;
;  make it all appear
;
WIDGET_CONTROL, sel_tplot_base, /realize


end