;+
; Project     : SOHO - CDS     
;                   
; Name        : TP_REDISPLAY
;               
; Purpose     : To redisplay current image/plot.
;               
; Explanation : Just redisplays current VDS/GIS data in last recorded state.
;               Used after widgets which desensitise the draw widget as this
;               deletes any plot and after a change of display mode.
;               
; Use         : tp_redisplay
;    
; Inputs      : None - all done in COMMON
;               
; Opt. Inputs : None
;               
; Outputs     : None
;               
; Opt. Outputs: None
;               
; Keywords    : None
;
; Calls       : DISPLAY routines
;               
; Restrictions: None
;               
; Side effects: None
;               
; Category    : Planning, technical
;               
; Prev. Hist. : None
;
; Written     : C D Pike, RAL, 17-Nov-1993
;               
; Modified    : Change NIS to VDS.  CDP, 7-Jul-94
;               Structure tag name change.  CDP, 12-Jul-94
;               Handle flag windows. CDP, 19-Sep-94 
;               Include colour bar.  CDP, 18-Oct-94
;
; Version     : Version 5, 18-Oct-94
;-            

pro tp_redisplay

;
;  COMMON for variables
;
@tplan_com

;
;  redisplay current data using parameters last set up
;
case display_state of
 'WON': begin
         erase
         window_mode = 'WIN'
         if num_windows eq 0 then begin
            flash_msg,info_line,'Warning: No windows defined yet.'
         endif
         if tp_obs.raster_p.detector eq 'N' then begin
            display_nis_win 
            tp_vds_axes
         endif else begin
            display_gis_win
         endelse
        end
 'ALL': begin
         window_mode = 'ALL'
         if tp_obs.raster_p.detector eq 'N' then begin
            tv,tp_bscale(VDS_image_data),0,0
            display_nis_win 
            tp_vds_axes
         endif else begin
            tp_plot_gis,GIS_data,GIS_band
            display_gis_win
         endelse
        end
;
;  if there are flag windows to display do them one at a time since there
;  is only a maximum of 3
;
 'FON': begin
         erase
         window_mode = 'FLG'
         n = where(tp_obs.line_w.flag eq 1)
         
         if n(0) eq -1 then begin
            flash_msg,info_line,'Warning: No flag windows defined yet.'
         endif else begin
            sp = !p.multi
            for i=0,n_elements(n)-1 do begin
               if tp_obs.raster_p.detector eq 'N' then begin
                  display_nis_win,n(i) 
                  tp_vds_axes
               endif else begin
                  if i eq 0 then !p.multi = [0,3,1]
                  display_gis_win,n(i)
               endelse
            endfor
            !p.multi = sp
         endelse
        end
  else:
endcase

;
;  redisplay line file descriptor
;
widget_control, wll_info_2, set_v=tp_obs.line_list.ll_desc

;
;  redo colour bar
;
tp_colbar

end