;+
; Project     :	SOHO - CDS
;
; Name        :	DEF_CDS_STUDY
;
; Purpose     : define a base CDS study structure
;
; Use         : DEF_CDS_STUDY,STUDY
;
; Inputs      : None.
;
; Opt. Inputs : None.
;
; Outputs     : STUDY = study definition
;
; Opt. Outputs: None.
;
; Keywords    : RASTERS = add a raster structure tag
;               FUND_ONLY = define fundamental part only
;
; Explanation : 
;
; Calls       : 
;
; Common      : None.
;
; Restrictions: None.
;
; Side effects: None.
;
; Category    : Planning
;
; Prev. Hist. : None.
;
; Written     :	Version 1, Zarro (ARC/GSFC) 31 October 1994
;               Version 2, Zarro (SM&A) 12 December 1998 - fixed FUND_ONLY bug
;-



pro def_cds_study,study,rasters=rasters,fund_only=fund_only

study =  {      STRUCT_TYPE:'CDS-STUDY',$
                STUDY_ID: -1,		$
                TITLE_ID:-1,            $
		OBS_PROG: 'UNNAMED',	$
		TITLE: 'UNTITLED',	$
		CATEGORY: 'S',		$
		N_RASTERS0: 0,		$
		VAR_POINT: 'Y',	$
                N_RASTER_DEF: 0,        $
		STUDYVAR: -1,		$
		SV_DESC: '',      	$
		DURATION0: 0.0,		$
		DURATION1: 0.0,		$
                ZONE_ID: 0    ,         $
		USABLE: 'Y'}

rast=	  {	CDS_STUDY_RAS,          $
			RAS_ID: 0,	$
			RAS_VAR: 0,	$
			POINTING: 1,	$
			INS_X: 0.0,	$
			INS_Y: 0.0,     $
                        N_REPEAT_R:1}

nrast=0
if exist(rasters) then nrast=fix(rasters)

fund_only=keyword_set(fund_only)

if fund_only then begin
 split_struct,study,'STUDYVAR',tstudy,vstudy
 study=rem_tag(tstudy,['N_RASTERS0','STRUCT_TYPE'])
endif

if nrast gt 0 then begin
 if fund_only then begin
  rast=rem_tag(rast,['RAS_VAR','N_REPEAT_R'])
  rast=rep_struct_name(rast,'CDS_F_ST_RAS')
 endif
 study=add_tag(study,replicate(rast,nrast),'RASTERS')
 study.n_raster_def=nrast
endif

return & end