;---------------------------------------------------------------------------
; Document name: mk_soho_setup.pro
; Created by:    Liyun Wang, GSFC/ARC, March 5, 1996
;
; Last Modified: Thu Apr 25 17:29:09 1996 (lwang@achilles.nascom.nasa.gov)
;---------------------------------------------------------------------------
;
PRO mk_soho_setup, resume=resume, go=go
;+
; PROJECT:
;       SOHO
;
; NAME:
;       MK_SOHO_SETUP
;
; PURPOSE:
;       Set up things for SOC people to run MK_SOHO *more* easily
;
; CATEGORY:
;       Planning, utility
;
; SYNTAX:
;       mk_soho_setup [, /resume]
;
; INPUTS:
;       None required.
;
; OPTIONAL INPUTS:
;       None.
;
; OUTPUTS:
;       None.
;
; OPTIONAL OUTPUTS:
;       None.
;
; KEYWORDS:
;       RESUME - Resume original settings
;       GO     - Set this keyword to launch MK_SOHO (no effect if
;                RESUME keyword is set)
;
; COMMON:
;       SETUP4MKSOHO (for internal use)
;
; RESTRICTIONS:
;       None.
;
; SIDE EFFECTS:
;       Values of several system variables are changed. To restore
;       them, run this procedure with the RESUME keyword.
;
; HISTORY:
;       Version 1, March 5, 1996, Liyun Wang, GSFC/ARC. Written
;
; CONTACT:
;       Liyun Wang, GSFC/ARC (Liyun.Wang.1@gsfc.nasa.gov)
;-
;
   ON_ERROR, 2
   COMMON setup4mksoho1, charsize, charthick, thickness

   IF KEYWORD_SET(resume) THEN BEGIN
      IF exist(charsize) THEN BEGIN
         !p.charsize = charsize
         !p.charthick = charthick
         !p.thick = thickness
         delvarx, charsize, charthick, thickness
      ENDIF
      RETURN
   ENDIF
   IF NOT fix_zdbase(/soho) THEN BEGIN
      PRINT, 'Warning: No SOHO database set!'
      PRINT, 'You are at your own risk if you run MK_SOHO.'
      RETURN
   ENDIF
   IF getenv('SOHO_EAP') EQ '' THEN BEGIN
      PRINT, 'SOHO_EAP not set. You cannot update DB with latest KAP.'
      PRINT, 'You cannot create CAP file for ECS either.'
   ENDIF

;---------------------------------------------------------------------------
;  Set SOHO_CAP
;---------------------------------------------------------------------------
   setenv, 'SOHO_CAP='+strep(getenv('ZDBASE'),'/database','/soho_cap')

   IF getenv('SSW_SETUP_DATA') EQ '' THEN $
      setenv, 'SSW_SETUP_DATA=/solarsoft/gen/setup/data'
   IF getenv('SSW_EIT') EQ '' THEN setenv, 'SSW_EIT=/solarsoft/soho/eit'

   charsize = !p.charsize
   charthick = !p.charthick
   thickness = !p.thick
   !p.charsize = 1.5
   !p.charthick = 2
   !p.thick = 2
   !priv = 3
   IF KEYWORD_SET(go) THEN mk_soho
   RETURN
END

;---------------------------------------------------------------------------
; End of 'mk_soho_setup.pro'.
;---------------------------------------------------------------------------