pro cnvrt2ref, hdr, level
;
;+
; NAME:
;	CNVRT2REF
;
; PURPOSE:
;	This procedure converts coordinate system to the standard coordinate 
;	system using the FITS keyword notation
;
; CATEGORY:
;	DATA_ANAL
;	Widgets.
;
; CALLING SEQUENCE:
;	CNVRT2REF, Hdr, Level
;
; INPUTS:
;	Hdr:	FITS header
;	Level:	String indicating level to define coordinate system:
;			'0.5', '1', '2'
;
; OUTPUTS:
;	None
;
; SIDE EFFECTS:
;	Keywords are added to the FITS header:
;		CRPIX, CRVAL, CROTA, CDELT, CTYPE, CUNIT
;
; MODIFICATION HISTORY:
;       RA Howard, NRL, 14 April 1996
;	Vers 1   14 Apr 1996, Initial Release
;
;	@(#)cnvrt2ref.pro	1.1 03/06/97 LASCO IDL LIBRARY
;-

nx = FXPAR (hdr,'SUMCOL')
ny = FXPAR (hdr,'SUMROW')
IF (nx EQ 0)  THEN nx=1
IF (ny EQ 0)  THEN ny=1
nx = nx * FXPAR(hdr,LEBXSUM)
ny = ny * FXPAR(hdr,LEBYSUM)
crpix1 = FXPAR(hdr,'R1COL')-19
crpix2 = FXPAR(hdr,'R1ROW')
ctype1 = 'SOLAR-X'
ctype2 = 'SOLAR-Y'
CASE level OF
'0.5':	BEGIN
           cdelt1 = FLOAT (nx)
           cdelt2 = FLOAT (ny)
           crval1 = ( crpix1 - 513 ) + 0.5 * cdelt1
           crval2 = ( crpix2 - 513 ) + 0.5 * cdelt2
           crota1 = 0.
           crota2 = 0.
           cunit1 = 'PIXEL'
           cunit2 = 'PIXEL'
        END
'1':    BEGIN
           cdelt1 = nx * .021
           cdelt2 = ny * .021
           crval1 = ( crpix1 - 513 ) * .021 + 0.5 * cdelt1
           crval2 = ( crpix2 - 513 ) * .021 + 0.5 * cdelt2
           crota1 = 0.
           crota2 = 0.
           cunit1 = 'MM'
           cunit2 = 'MM'
        END
'2':    BEGIN
           ps = PLATESCALE(hdr)
           cdelt1 = nx * ps
           cdelt2 = ny * ps
           crval1 = ( crpix1 - 513 ) * ps + 0.5 * cdelt1
           crval2 = ( crpix2 - 513 ) * ps + 0.5 * cdelt2
           crota1 = SOLAR_ROLL (hdr)
           crota2 = SOLAR_ROLL (hdr)
           cunit1 = 'ARCSEC'
           cunit2 = 'ARCSEC'
        END
ELSE:   BEGIN
           PRINT,'%CNVRT2REF, Level not recognized = ',level
           RETURN
        END
ENDCASE
FXADDPAR,hdr,'CRPIX1',crpix1
FXADDPAR,hdr,'CRPIX2',crpix2
FXADDPAR,hdr,'CRVAL1',crval1
FXADDPAR,hdr,'CRVAL2',crval2
FXADDPAR,hdr,'CROTA1',crota1
FXADDPAR,hdr,'CROTA2',crota2
FXADDPAR,hdr,'CTYPE1',ctype1
FXADDPAR,hdr,'CTYPE2',ctype2
FXADDPAR,hdr,'CUNIT1',cunit1
FXADDPAR,hdr,'CUNIT2',cunit2
FXADDPAR,hdr,'CDELT1',cdelt1
FXADDPAR,hdr,'CDELT2',cdelt2
RETURN
END