function cnvrt_ip,hdr
;+
; NAME:				CNVRT_IP
;
; PURPOSE:			Convert image processing steps into one 
;                               character per step codes.
;
; CATEGORY:			REDUCTION
;
; CALLING SEQUENCE:		Result = CNVRT_IP(Hdr)
;
; INPUTS:			Hdr:    Header Structure
;
; OPTIONAL INPUTS:		None
;	
; KEYWORD PARAMETERS:		None
;
; OUTPUTS:			Result:  String containing the IP characters
;
; OPTIONAL OUTPUTS:		None
;
; COMMON BLOCKS:		None
;
; SIDE EFFECTS:			None
;
; RESTRICTIONS:			None
;
; PROCEDURE:			
;
; EXAMPLE:
;
; MODIFICATION HISTORY:		Written, RA Howard, NRL
;    VERSION 1   rah   30 Nov 1995
;    VERSION 2   sep   31 May 1996  Modified to read data from cnvrt_ip.dat
;    VERSION 3   rah   14 Jun 1996  Modified ip_arr structure names
;
;	@(#)cnvrt_ip.pro	1.2 03/06/97 LASCO IDL LIBRARY
;
;-
;
;  Build up the compression scheme code:
;
COMMON CNVRT_IP, ip_arr

   ;** if we haven't read in the include file then read it
   IF (DATATYPE(ip_arr) EQ 'UND') THEN ip_arr = READ_IP_DAT()

   s=''
   num_ip = hdr.NUM_IP
   IF (num_ip GT 0) THEN BEGIN
      FOR i=0,hdr.num_ip-1 DO BEGIN
         ind = WHERE(hdr.leb_proc(i) EQ ip_arr.ip_num)
         IF (ind(0) NE -1) THEN s = s+ip_arr(ind).ip_char
      ENDFOR
   ENDIF
   IF (s EQ '') THEN s='N'
   RETURN, s

END