PRO PLOT_LASCO_SPECTRA,Tel,SINGLE=SINGLE
;
;+
; NAME:
;	PLOT_LASCO_SPECTRA
;
; PURPOSE:
;	This procedure plots the LASCO filter spectral data
;
; CATEGORY
;	CALIBRATION
;
; CALLING SEQUENCE:
;	PLOT_LASCO_SPECTRA,Tel
;
; INPUTS:
;	Tel:	string containing the telescope: 'c1','c2','c3'
;
; KEYWORD PARAMETERS:
;	SINGLE:	If set then a single plot is made.  The default is
;		to plot all of the spectra.
;
; OUTPUTS:
;	Generates a plot
;
; MODIFICATION HISTORY:
;	Written by R.A. Howard, NRL
;
; @(#)plot_lasco_spectra.pro	1.1 07/31/97 :NRL Solar Physics
;
;-
CASE STRLOWCASE(tel) OF
   'c1':  BEGIN
            fn=['orang','na','fexiv','caxv','fex','ha']
            names=['Orange','Na','Fe XIV','Ca XV','Fe X','H alpha']
            !x.range = [5000,8000]
          END
   'c2':  BEGIN
            fn=['blue','orang','dpred','ha','focus']
            names=['Blue','Orange','Red','H alpha','Neutral Density']
            !x.range = [4000,9000]
          END
   'c3':  BEGIN
            fn=['clear','blue','orang','dpred','ir','ha']
            names=['Clear','Blue','Orange','Red','IR','H alpha']
            !x.range = [4000,10000]
          END
   else:  BEGIN
            PRINT,'%ERROR PLOT_LASCO_SPECTRA: Telescope not recognized'
            RETURN
          END
ENDCASE
fn=STRLOWCASE(tel)+'_'+fn+'.dat'
nf = n_elements(fn)
IF (KEYWORD_SET(SINGLE)) THEN BEGIN
    nfa=single-1
    nfb=single-1
    IF ((nfa LT 0) OR (nfa GE nf))  THEN BEGIN
       PRINT,'%ERROR PLOT_LASCO_SPECTRA: single plot value out of range'
       RETURN
    ENDIF
    tit='LASCO '+STRUPCASE(tel)+' '+names(nfa)+' Filter'
ENDIF ELSE BEGIN
    nfa=0
    nfb=nf-1
    tit='LASCO '+STRUPCASE(tel)+' '+' Filter Transmittance'
ENDELSE
FOR i=nfa,nfb DO BEGIN
print,fn(i)
    READ_LASCO_SPECTRA,fn(i),wl,int,np
    IF (i EQ nfa) THEN BEGIN
       PLOT,wl,int,yrange=[0,100], $
            title = tit, xtitle='Wavelength [A]',  $
            ytitle='Transmission [%]'
    ENDIF ELSE BEGIN
       OPLOT,wl,int,line=i
    ENDELSE
ENDFOR
!x.range=''
RETURN
END