pro STDIMGPLOT,a,hdr
;+
;Name:
;       STDIMGPLOT
;
;Purpose:
;    generates standard plots for image analysis
;
;Usage:
;       STDIMGPLOT,A,Hdr
;
;Inputs:
;       A   = image
;       Hdr = FITS header, header structure
;
; SCCS variables for IDL use
; 
; %W% %H% :NRL Solar Physics
;
;-
IF (DATATYPE(hdr) EQ 'STC')  THEN BEGIN
   tel=hdr.detector
   shdr = hdr
ENDIF ELSE BEGIN
   tel=FXPAR(hdr,'TELESCOP')
   IF (tel EQ 'MK3')  THEN shdr=MLO_FITSHDR2STRUCT(hdr) $
                      ELSE shdr=LASCO_FITSHDR2STRUCT(hdr)
ENDELSE
naxis1 = shdr.NAXIS1
naxis2 = shdr.NAXIS2
!p.multi=[0,3,2,1,1]
!x.title='Column Number'
!y.title='DN'
for i=0,2 do begin
    case I of
        0:  row = naxis2 /2
        1:  row = naxis2 /4
        2:  row = (3 * naxis2 /4)>naxis2
    endcase
    rs = strtrim(string(row),2)
    s = stdev(a(*,row-1))
    plot,a(*,row-1),/ynozero,title='Line  '+rs+ $
         '  StdDev =  '+strtrim(string(s),2)
endfor
!x.title='Row Number'
col = naxis1 /2
cs = strtrim(string(col),2)
s=stdev(a(col-1,*))
plot,a(col-1,*),/ynozero,title='Column  '+cs+ $
     '  Std Dev = '+strtrim(string(s),2)
lasco_sidebar,shdr
row = naxis2 /2
!p.multi=[0,3,2,1,1]
!p.title='Histogram of Line '+strtrim(string(row),2)
!y.title='Frequency'
!x.title='Channel No'
!p.psym=0
plot_io,histogram(a(*,row-1),min=0)>.1
!p.title='Histogram of Entire Image'
plot_io,histogram(a,min=0)>.1
sd = fltarr(1024)
!x.title='Row Number'
!y.title='DN'
for i=0,naxis2-1 do sd(i)=average(a(*,i))
plot,sd,title='Line Average',/ynozero
empty
for i=0,naxis2-1 do sd(i)=stdev(a(*,i))
plot,sd,title='Std Dev',/ynozero
lasco_sidebar,shdr
!p.multi=[0,3,2,1,0]
!x.title='Row Number'
!y.title='DN'
for i=0,naxis2-1 do sd(i)=median(a(*,i))
mmn = MIN(sd,max=mmx)
IF (mmx-mmn LE 5)  THEN $
   plot,sd,title='Line Medians',/ynozero,yrange=[mmn-2,mmx+2] $
ELSE $
   plot,sd,title='Line Medians',/ynozero
empty
lasco_sidebar,shdr
!p.multi=0
empty
!p.title=''
!x.title=''
!y.title=''
!p.psym=0
return
end