pro plot_monexp_std,tel,dtea,dteb,ps=ps
;+
;
; NAME:
;	PLOT_MONEXP_STD
;
; PURPOSE:
;         This procedure reads in the output data file from MONITOR-EXP.PRO,
;         and makes standard plots
;
; CATEGORY:
;         DATA_ANAL
;
; CALLING SEQUENCE:
;
;         PLOT_MONEXP_STD,Tel,Dtea,Dteb
;
; INPUTS:
;         Tel:	String giving the telesope name, eg. 'c1'
;         Dtea:	String giving the starting date, eg, '960601'
;         Dteb:	String giving the ending date, eg, '960607'
;
; KEYWORD PARAMETERS:
;         PS:	If set, create a postscript file
;
; OUTPUTS:
;         None
;
; SIDE EFFECTS:
;         Generates plot files
;
; RESTRICTIONS:
;        NONE
;
; PROCEDURE:
;
;
; MODIFICATION HISTORY:
;         
;
;	@(#)plot_monexp_std.pro	1.2 09/26/97 LASCO IDL LIBRARY
;
;-

READ_MONEXP_DATA,tel,dtea,dteb

filter=STRCOMPRESS(GET_MONEXP_DATA('FILTER'),/remove_all)
funiq = STR_UNIQUE(filter)
polar = STRCOMPRESS(GET_MONEXP_DATA('POLAR'),/remove_all)
puniq = STR_UNIQUE(polar)
nf = n_elements(funiq)
np = n_elements(puniq)
expt = GET_MONEXP_DATA('EXPT')
date = GET_MONEXP_DATA('DATE')
time = GET_MONEXP_DATA('TIME')
dte = REPLICATE({cds_int_time},n_elements(date))
dte.mjd = date
dte.time = time*1000
FOR jf=0,nf-1 DO BEGIN
    FOR ip=0,np-1 DO BEGIN
        w=where(filter EQ funiq(jf) AND polar EQ puniq(ip),nw)
        IF ((w(0) NE -1) AND (nw GT 5))  THEN BEGIN
           bias = OFFSET_BIAS(tel,'c',dte(w(0)).mjd)
           !y.title='DN/sec'
           avg = GET_MONEXP_DATA('AVG_WHOLE')-bias
           !p.title='Average of Entire Image: ('+tel+':'
           !p.title=!p.title+funiq(jf)+','+puniq(ip)+')'
           IF (KEYWORD_SET(ps))  THEN PS_SETUP,0
           UTPLOT,dte(w),avg(w)/expt(w),psym=-1
           med = GET_MONEXP_DATA('MED_WHOLE')-bias
           !p.title='Median of Entire Image: ('+tel+':'
           !p.title=!p.title+funiq(jf)+','+puniq(ip)+')'
           UTPLOT,dte(w),med(w)/expt(w),psym=-1
           mode = GET_MONEXP_DATA('MOD_WHOLE')-bias
           !p.title='Mode of Entire Image: ('+tel+':'
           !p.title=!p.title+funiq(jf)+','+puniq(ip)+')'
           UTPLOT,dte(w),mode(w)/expt(w),psym=-1
           !y.title='DN'
           sig = GET_MONEXP_DATA('SIG_WHOLE')
           !p.title='Standard Deviation of Entire Image: ('+tel+':'
           !p.title=!p.title+funiq(jf)+','+puniq(ip)+')'
           UTPLOT,dte(w),sig(w),psym=-1
           !y.title='Number of Blocks'
           nz = GET_MONEXP_DATA('NZ_WHOLE')/1024
           !p.title='Number of Missing Blocks: ('+tel+':'
           !p.title=!p.title+funiq(jf)+','+puniq(ip)+')'
           UTPLOT,dte(w),nz(w),psym=-1
           a = GET_MONEXP_DATA('AVERAGE')
           IF (KEYWORD_SET(ps))  THEN PS_SETUP,1
           FOR j=0,N_ELEMENTS(w)-1,80 DO BEGIN
               TVERASE
               b=TVRD()
               b=b+255
               TV,b
               s=tel+'('+funiq(jf)+','+puniq(ip)+')'
               da = UTC2STR(date(w(j)),/date_only)
               k = (j+79)>(n_elements(w)-1)
               db = UTC2STR(date(w(k)),/date_only)
               XYOUTS,20,400,s+' '+da+' - '+db
               FOR jj=j,k DO BEGIN
                   b = BYTSCL(a(*,*,w(jj))/expt(w(jj)),min=0,max=450)
                   TV,REBIN(b,64,64),jj-j+20
               ENDFOR
               IF (KEYWORD_SET(ps))  THEN BEGIN
                  b = TVRD()
                  PS_SETUP,0
                  TV,b
                  PS_SETUP,1
               ENDIF
           ENDFOR
        ENDIF
    ENDFOR
ENDFOR
RETURN
END