function getc2c3pol,mon,day,cam,sttime

;PURPOSE: 
;     Return a polarized intensity image for c2 or c3.
;
;
;INPUTS:
;	mon = int:	month
;	day = int:	day
;	cam = string:	camera
;	sttime = float:	fraction of day of begin of CR
;
;ROUTINES CALLED:
;    getmelasco2.pro
;
;Author: Julia Kraemer, NRL, June 7, 1996
;
;MODIFIED:
;	961023 by N. Rich	made into function called by newc2c3carr2
;	961029 by N. Rich	added query to images in ares:/data/wang/pol
;	961107 by N. Rich	allows 1024x512 pol files form early May 1996
;	961118 by N. Rich	added time mods for specific days, cameras
;

;COMMON carrvar, cx,cy,rconv,polims


i=-1
polim=fltarr(512,512)
date_struct={cds_ext_time,year:1996,month:mon,day:day,hour:0,minute:0,second:0,millisecond:0}
date_obs=utc2str(date_struct,/ECS,/date_only)
IF mon eq 8 THEN poldir='aug96/'
IF mon eq 9 THEN poldir='sep96/'
IF mon eq 10 THEN poldir='oct96/'
IF mon eq 11 THEN poldir='nov96/'

IF mon GE 8 AND mon LE 9 THEN BEGIN
   polims=findfile('/net/ares/data/wang/pol/'+poldir+STRUPCASE(cam)+'-p-*.fts')
   print,'Found ',n_elements(polims),' polarized images.'
   REPEAT BEGIN
	i=i+1
	h=headfits(polims(i))
   ENDREP UNTIL fxpar(h,'date-obs') EQ date_obs OR i GE (n_elements(polims)-1)
   IF i GE (n_elements(polims)-1) THEN polim(*,*)=0 ELSE BEGIN
      print,'Now reading '+polims(i)
      polim=readfits(polims(i))
      IF polims(i) EQ '/net/ares/data/wang/pol/sep96/C2-p-21003848.fts' THEN polim(*,*) = 0
   ENDELSE
ENDIF ELSE BEGIN
       
    tt='00:00:00'
    
    IF cam eq 'c3' AND day eq 28 AND mon eq 6 THEN tt='14:04:00'
    IF day eq 21 AND mon eq 5 THEN tt='20:00:00'
    IF cam EQ 'c3' AND day EQ 22 AND mon EQ 6 THEN tt='23:00:00'

    imp60= getmelasco2(mon,day,96,cam,time=tt,polar='+60 Deg',HEADER=hp60, ysize=512)         
    sz=SIZE(imp60)
    IF sz(0) eq 0 THEN imp60=fltarr(512,512)         
	  
    imm60=getmelasco2(mon,day,96,cam,time=tt,polar='-60 Deg',header=hm60, ysize=512)
    sz=SIZE(imm60)
    IF sz(0) eq 0 THEN imm60=fltarr(512,512)
			       
    im0=getmelasco2(mon,day,96,cam,time=tt,polar='0 Deg',header=h0, ysize=512)
    sz=SIZE(im0)
    IF sz(0) eq 0 THEN im0=fltarr(512,512)
    
    
    IF median(im0) ne 0 AND median(imm60) ne 0 AND median(imp60) ne 0 THEN BEGIN
	    
	    imp60=float(imp60)
		biasp60=fxpar(hp60,'OFFSET')
		expp60=fxpar(hp60,'exptime')
		imp60=(imp60-biasp60)/expp60
	
	    imm60=float(imm60)
	    biasm60=fxpar(hm60,'offset')
	    expm60=fxpar(hm60,'exptime')
	    imm60=(imm60-biasm60)/expm60
	    
	    im0=float(im0)
	    bias0=fxpar(h0,'offset')
	    exp0=fxpar(h0,'exptime')
	    im0=(im0-bias0)/exp0
    
	j1=imp60
	j2=im0
	j3=imm60
	
	IF cam eq 'c3' THEN BEGIN
		j3=1.0812*j3  
		j2=0.965620*j2
		j1=j1
	ENDIF
	
	A=((j1+j3)/2-j2)*4/3
	B=(j1-j3)*2/sqrt(3)
	polim=sqrt(A^2+B^2)
;	tvscl,polim<80
    ;    IF cam eq 'c2' THEN polim=polim<30
    ;    IF cam eq 'c3' THEN polim=polim<10
    ENDIF
ENDELSE

IF sz(1) EQ 1024 THEN BEGIN
   bkgrd = FLTARR(512,512)
   shrunk=rebin(polim,512,256)
   bkgrd(0,256)=shrunk
   polim = bkgrd
ENDIF

RETURN,polim

end 	; getc2c3pol