pro make_all_days,tel,stdte,endte,off=off, FILTER=filter, POLAR=polar,wlu=wlu, QL=ql, ANYSIZE=anysize, NOREBIN=norebin, ROLLED=rolled, VERBOSE=verbose
;
;+
; NAME:
;	MAKE_ALL_DAYS
;
; PURPOSE:
;	This procedure is an easy interface to the MK_DAILY_MED procedure
;
; CATEGORY:
;	LASCO SYNOPTIC
;
; CALLING SEQUENCE:
;	MAKE_ALL_DAYS,Tel,Stdte,Endte
;
; INPUTS:
;	Tel:	Telescope to be processed, (string), eg. 'C1','C2','C3'
;	Stdte:	The starting date specified as a string: YYMMDD, eg. 960601
;	Endte:	The ending date specified as a string: YYMMDD, eg, 960630
;
; OUTPUTS:
;	This function generates images in $MONTHLY_IMAGES of the daily
;	medians for the specfied telescope, and for each day specfied by the
;	starting and ending dates.
;
; KEYWORDS:
;	QL:	If set then use quick look date, else use level 0 data
;	FILTER:	String denoting the filter position.  The default depends on 
;		the telescope:
;			C1:  FeXIV
;			C2:  Orange
;			C3:  Clear
;			C4:  Clear
;	POLAR:	String denoting the polarizer position.  The default depends on
;		the telescope:
;			C1:  Clear
;			C2:  Clear
;			C3:  Clear
;			C4:  304A
;	WLU:	String denoting the upper FP wavelength of an interval. 
;	ANYSIZE:	Accept images with any dimensions GT 256
;	NOREBIN:	Do not rebin images to 512x512
;	ROLLED:		Save result in 'daily/rolled' directory; set equal to roll angle (CROTA)
;	VERBOSE:	Print information on rows during loop
;
; RESTRICTIONS:
;	
;	
; PROCEDURE:
;	A loop is generated between the start and end dates, in which the
;	routine MK_DAILY_MED is called for each day.
;
; EXAMPLE:
;	To make all the daily median images for the month of June, 1996 for
;	C3:
;
;		MAKE_ALL_DAYS,'c3','960601','960630'
;
; MODIFICATION HISTORY:
; 	Written by:	RA Howard, 20 October, 1996
;	9/20/99   NBR	Had to add QL to mk_daily_med call
;	12/1999	  NBR	Make y2k compliant; add MK_DAILY_MED keywords
;	07/2000   NBR   Add ROLLED keyword
;	5/2/2002, NBR	Add keyword descriptions
;
;	07/14/03 @(#)make_all_days.pro	1.5 LASCO IDL LIBRARY
;-
;

IF strlen(stdte) GT 6 THEN BEGIN
   st = str2utc(stdte)
   en = str2utc(endte)
ENDIF ELSE BEGIN
   st = yymmdd2utc(stdte)
   en = yymmdd2utc(endte)
ENDELSE
;
jdstart = st.mjd
jdend = en.mjd
;
;  For each day call the routine to compute the daily median
;
FOR i=jdstart,jdend DO BEGIN
    IF (STRUPCASE(tel) eq 'C1')  THEN BEGIN
       IF (KEYWORD_SET(off))  THEN MK_DAILY_C1_MED,tel,i,off=off,ql=ql $
                              ELSE MK_DAILY_C1_MED,tel,i,off=0,ql=ql
    ENDIF ELSE BEGIN
       MK_DAILY_MED,tel,i,FILTER=filter, POLAR=polar,wlu=wlu, QL=ql, ANYSIZE=anysize, $
		NOREBIN=norebin, ROLLED=rolled, VERBOSE=verbose
    ENDELSE
ENDFOR
RETURN
END