function makebasecarr,time1_str,cam,radii,wlimb,mapsize

;NAME:       makebasecarr
;
;PURPOSE:    Make a background carrington map using images from 
;            /net/corona/cplex3/monthly as the background map to
;            use for making difference carrington maps
;
;INPUTS:     time1_str   STRING   day for which to make minimum
;	     cam	 STRING   camera (c2 or c3)
;	     radii	INTARR   contains radii for carrmaps
;	     wlimb	STRING   'el' or 'wl'
;
; Author: Julia Kraemer, NRL, Jan, 1997
;
; Modified 970109 by N. Rich	make into a function
;	970115 by N. Rich	change monthly directory; changed limb to wlimb;
;				remove num_r parameter
;	970227 by N. Rich	add intensity normalization
;	970407 by N. Rich	use Scott's getbkgimg to get c3 background
;	970514 by N. Rich	use mapsize
;
;

strip = fltarr(181)
sz=size(radii)
num_r=sz(1)
   
IF cam eq 'c2' THEN BEGIN
   cx=512
   cy=505
   rconv=79
ENDIF
IF cam eq 'c3' THEN BEGIN
  cx=518
  cy=530
  rconv=18
ENDIF

IF cam eq 'c2' THEN BEGIN
    basefile='/net/corona/export/raid2/monthly/c2min.fts'
    exp=25.
    print,'basefile= ', basefile
    baseim=float(readfits(basefile))/exp
ENDIF

IF cam eq 'c3' THEN BEGIN
   exp=19.
   year= '96'	;strmid(time1_str,2,2)
   month=strmid(time1_str,5,2)
   day=strmid(time1_str,8,2)
   date=year+month+day
   ff=findfile('/net/corona/cplex2/lz_data/level_05/'+date+'/'+cam+'/*.fts')
   sz=SIZE(ff)
   num_ff=sz(1)
   print,'Basefile for ',ff(num_ff/2)
   dummy = lasco_readfits(ff(num_ff/2),test_hdr,/no_img)
   baseim = getbkgimg(test_hdr,/ffv)/test_hdr.exptime
;   stop
ENDIF



;  ** Begin intensity normalization. **
   a1=1
   a2=1
   squ1=baseim(469:511,778:798)
   squ2=baseim(512:554,778:798)
   ch1=where(squ1 LE 0,null1)
   ch2=where(squ2 LE 0,null2)
   IF null1 GT 2 THEN a1=0
   IF null2 GT 2 THEN a2=0
   IF a1 EQ a2 THEN BEGIN
   	a1 = 0.5
   	a2 = 0.5
   ENDIF
   med1=median(squ1)
   med2=median(squ2)
   int_corr=a1*med1 + a2*med2
   print,'int_corr = ',int_corr,'    null1 =',null1,'    null2 =',null2
   baseim=10*baseim/int_corr 
   
;  ** End intensity normalization. **


basecarr=fltarr(mapsize,181,num_r)
basestrip=fltarr(1,181)
FOR r=0,num_r-1 DO BEGIN
   r0=radii(r)*rconv
   rn=r0
   FOR i=0,180 DO BEGIN
	theta=i-90
	th=theta*!PI/180
	IF wlimb eq 'wl' THEN xcoor=rn*cos(th)+cx
	IF wlimb eq 'el' THEN xcoor=-rn*cos(th)+cx
	ycoor=rn*sin(th)+cy
        basestrip(i)=INTERPOLATE(baseim,xcoor,ycoor)
   ENDFOR   ;	i loop
   FOR k=0,mapsize-1 DO basecarr(k,*,r)=basestrip(*)
print,'r=',r,'                radii(',r,') =',radii(r)
ENDFOR

return,basecarr

END