pro slide_carrmap, limb, r
;
; Purpose:	Display carrington maps in a scrollable format
;
; Optional Inputs:
;	limb	STRING	'wl', 'el' or search parameter
;	r	FLOAT	radius of desired map
;
; Written 980917 by Nathan Rich, Interferometrics/NRL
;
;

IF N_PARAMS() LT 2 THEN BEGIN
	limb = ''
	r = 2.5
	read,'Please enter limb or search param. (el/wl): ',limb
	read,'Please enter desired radius: ',r
ENDIF


radii = [2.5,3,4.5,5,7,10,15,20,25]

loc = find_closest(r,radii)
r = radii(loc)

IF r LT 2.5 THEN cam = 'c1' ELSE $
IF r LT 5 THEN cam = 'c2' ELSE cam = 'c3'

IF cam EQ 'c3' THEN BEGIN
	rstr = strtrim(string(r,format='(i2.2)'))
	upper = 1.085 - 0.0033*r
	lower = 0.89 + 0.005*r
ENDIF
IF cam EQ 'c2' THEN BEGIN
	rstr = strtrim(string(r*10,format='(i2.2)'))
	upper = 1.8 - 0.05*r
	lower = 0.73
ENDIF
IF cam EQ 'c1' THEN rstr = strtrim(string(r*100,format='(i3.2)'))

list = findfile('/net/corona/cplex3/carrmaps/'+cam+limb+'*_'+rstr+'*')
print,list

cmap = readfits(list(0),hdr)
cmap = shift(cmap,1)			; ** fix for blank first column
IF cam EQ 'c2' THEN cmap = REBIN(cmap,720,181)
mapmax=upper*median(cmap)
mapmin=lower*median(cmap)
bigmap = bytscl(reverse(cmap<mapmax>mapmin))
bsz = size(bigmap)
last = n_elements(list) - 1

FOR i = 1,last DO BEGIN
   cmap = readfits(list(i),hdr)
   cmap = shift(cmap,1)			; ** fix for blank first column
   IF cam EQ 'c2' THEN cmap = REBIN(cmap,720,181)
   mapmax=upper*median(cmap)
   mapmin=lower*median(cmap)
   sz = size(cmap)
   dummy = fltarr(sz(1)+bsz(1),181)
   dummy(0,0) = bigmap
   dummy(bsz(1)-1,0) = bytscl(reverse(cmap<mapmax>mapmin))
   bigmap = dummy
   bsz = size(bigmap)
ENDFOR

print
print,'Maps shown for ',STRUPCASE(cam),' Rsun =',r
print
IF cam EQ 'c2' THEN print,' NOTE: C2 Maps are shown twice the size of C3 maps.'
print
slide_image,bigmap

END