PRO BUILD_LASCO_HELP
;                   
;+
; Project     : SOHO - LASCO/EIT
;                   
; Name        : BUILD_LASCO_HELP
;               
; Purpose     : Create html help files for all LASCO IDL library routines.
;               
; Use         : BUILD_LASCO_HELP
;    
; Inputs      : None.
;               
; Outputs     : None.
;               
; Keywords    : None.
;
; Restrictions: Must have write permission to $NRL_LIB/lasco directories.
;               
; Side effects: Creates files in the subdirectories of $NRL_LIB/lasco of the form:
;  		help_subdir.html.  Ex. help_data_anal.html
;               
; Category    : Help.
;               
; Prev. Hist. : None.
;
; Written     : Scott Paswaters, NRL, Mar. 1996.
;               
; Modified    : RAH, NRL, 3/31/99.  Added inout and expfac directories
;		NBR, NRL, 9/16/10 - Rename las-c2
;
; Version     : 
;
; @(#)build_lasco_help.pro	1.6 09/16/10 :LASCO IDL LIBRARY
;
;-            

;______________________________________________________________________________
;


   idl_dir = GETENV('NRL_LIB')
   IF (idl_dir EQ '') THEN BEGIN
      PRINT, 'Unknown NRL_LIB environment variable.  Returning'
      RETURN
   ENDIF

   lasco_dir = idl_dir+'/lasco/'
   ;sub_dirs = FINDFILE(lasco_dir)
   sub_dirs = [ $
                'astrometry', $
                'beta', $
                'cme', $
                'convert', $
                'data_anal', $
                'database', $
                'display', $
		'expfac', $
                'exposure', $
		'inout', $
                'las_c2', $
                'movie', $
                'old', $
                'packets', $
                'polariz', $
                'reduce', $
                'synoptic', $
                'util']

   FOR d=0, N_ELEMENTS(sub_dirs)-1 DO BEGIN

      pros = FINDFILE(lasco_dir+sub_dirs(d)+'/*.pro')
      pros2 = FINDFILE(lasco_dir+sub_dirs(d)+'/*/*.pro')
      pros = [pros,pros2]
      ind = WHERE(pros NE '')
      IF (ind(0) GE 0) THEN BEGIN
         pros = pros(ind)
         good = BYTARR(N_ELEMENTS(pros))
         FOR i=0, N_ELEMENTS(pros)-1 DO BEGIN
            BREAK_FILE, pros(i), a1, a2, a3, a4
            IF ( (STRMID(a3,0,1) NE ',') AND (a3 NE 's') AND (a3 NE 'p') ) THEN good(i) = 1
         ENDFOR
         ind = WHERE(good EQ 1)
         IF (ind(0) GE 0) THEN BEGIN
            pros = pros(ind)
            LASCO_MK_HTML_HELP, pros, lasco_dir+sub_dirs(d)+'/help_'+sub_dirs(d)+'.html'
            IF (DATATYPE(allpros) EQ 'UND') THEN allpros = pros ELSE allpros = [allpros,pros]
         ENDIF
      ENDIF

   ENDFOR

   LASCO_MK_HTML_HELP, allpros, lasco_dir+'/help_all.html'

END