;
;IDL> PLOT_KP, '1997/03/08', '1997/03/12', TAI=tai, KP=kp
;
; kp and tai time will be returned in tai and kp variables
;

PRO PLOT_KP, date1, date2, TAI=kp_tai, KP=kp

COMMON PLOT_KP_COMMON, kp_data

   IF (DATATYPE(kp_data) EQ 'UND') THEN BEGIN
      ;PRINT, '%%PLOT_KP: Reading Kp data...'
      ;kp_data=READKP('/net/argus/data2/scott/halo/kp_data/kp_all.txt')
      ;PRINT, '%%PLOT_KP: Done.'
      RESTORE, GETENV('NRL_LIB')+'/lasco/data/kp_data.sav'
   ENDIF

   d1=UTC2TAI(ANYTIM2UTC(date1))
   d2=UTC2TAI(ANYTIM2UTC(date2))

   ind = WHERE((kp_data.date GE d1) AND (kp_data.date LE d2))
   len = N_ELEMENTS(ind)
   IF (len LE 1) THEN BEGIN
      PRINT, '%%%PLOT_KP: Currently only has kp data from ', UTC2STR(TAI2UTC(kp_data(0).date),/ECS), ' to ',$
              UTC2STR(TAI2UTC(kp_data(N_ELEMENTS(kp_data)-1).date),/ECS)
      RETURN
   ENDIF
   kp=kp_data(ind).kp
   kp_tai=kp_data(ind).date

   kp_utc=TAI2UTC(kp_tai)

   dayb=WHERE(kp_utc.time EQ 0)
   xtickname=STRARR(N_ELEMENTS(dayb))

   xtickv=kp_tai(dayb)	;** xrange is tai time
   xticks=N_ELEMENTS(xtickv)-1
   xtickname = STRMID(UTC2STR(TAI2UTC(xtickv), /DATE_ONLY),5,5)
   cs=1.5

   IF N_ELEMENTS(dayb) GT 30 THEN BEGIN
      xtickname=0
      xtickv=0
      xticks=0
   ENDIF

   PLOT, kp, /NODATA, XTICKS=xticks, XTICKNAME=xtickname, XTICKV=xtickv, $
      XMINOR=8, XRANGE=[kp_tai(0),kp_tai(len-1)], XSTYLE=1, XTHICK=2, YTHICK=2, $
      YSTYLE=1, YTICKS=9, YRANGE=[0,9], YTICKNAME=STRING(INDGEN(9)), /DATA, $
      CHARSIZE=cs, XTITLE=STRMID(UTC2STR(TAI2UTC(kp_tai(0)),/ECS, /TRUNCATE),0,16)+ ' - '+$
      STRMID(UTC2STR(TAI2UTC(kp_tai(len-1)),/ECS, /TRUNCATE),0,16), $
      BACKGROUND=255, COLOR=0

;** set up color table
 LOADCT, 0
 TVLCT, 0,255,0, 1      ;** load green into entry 2
 TVLCT, 0,255,0, 2      ;** load green into entry 2
 TVLCT, 0,255,0, 3      ;** load green into entry 2
 TVLCT, 255,255,0,4     ;** load yellow into entry 4
 TVLCT, 255,0,0, 5      ;** load red into entry 1
 TVLCT, 255,0,0, 6      ;** load red into entry 1
 TVLCT, 255,0,0, 7      ;** load red into entry 1
 TVLCT, 255,0,0, 8      ;** load red into entry 1
 TVLCT, 255,0,0, 9      ;** load red into entry 1

   XYOUTS, 0.1, 0.3, /NORMAL,'K-Index (', ORIENTATION=90, COLOR=255, CHARSIZE=cs
   XYOUTS, 0.1, 0.46, /NORMAL,'K<4  ', ORIENTATION=90, COLOR=1, CHARSIZE=cs
   XYOUTS, 0.1, 0.54, /NORMAL,'K=4  ', ORIENTATION=90, COLOR=4, CHARSIZE=cs
   XYOUTS, 0.1, 0.62, /NORMAL,'K>=5', ORIENTATION=90, COLOR=6, CHARSIZE=cs
   XYOUTS, 0.1, 0.69, /NORMAL,')', ORIENTATION=90, COLOR=255, CHARSIZE=cs

   margin=.3D*60*60
   hrs3 = 3.D*60*60
   FOR i=0, len-2 DO BEGIN
      x1=kp_tai(i)+margin & x2=kp_tai(i)+hrs3-margin
      y1=0 & y2=kp(i)
      POLYFILL, [x1,x2,x2,x1], [y1,y1,y2,y2], /DATA, COLOR=y2>1
   ENDFOR

END
