pro plot_roll, dt0,dt1, dt_arr, rollarr, missing, HOUR=hour, MINUTE=minute, PLOT_ONLY=plot_only, zoom=zoom

; Plots roll angle of SOHO from SO_AT_DEF* files between two dates input 
; (inclusive) and saves it as a gif file.
;
; INPUTS
;  dt0		STRING	Start date
;  dt1		STRING	End date
;
; OPTIONAL OUTPUTS/INPUTS
;  dt_arr	STRARR	Array of dates and times
;  rollarr 	FLTARR	Array of roll angles at dt_arr
;  missing	BYTARR	Binary array indicating whether date/time has invalid roll angle
;
; KEYWORDS
;  HOUR		Plot with increments of 1 hour
;  MINUTE	Plot with increments of 1 minute
;	(default is increment of 1 day)
;  PLOT_ONLY	Use arguments to do plot and do not compute
;  /ZOOM    Generate a second plot zooming in to nominal roll
;
; Modified:
;  Written by Nathan Rich, NRL/Interferometrics
;  10. 1.01, nbr - Update
;   3.13.02, nbr - Update for 24-bit display
;
; %W% %H% - IDL NRL LASCO Library
;
;-


IF strlen(dt0) EQ 6 THEN BEGIN
	utc0 = yymmdd2utc(dt0)
	utc1 = yymmdd2utc(dt1)
ENDIF ELSE BEGIN
	utc0 = str2utc(dt0)
	utc1 = str2utc(dt1)
	dt0 = utc2yymmdd(utc0)
ENDELSE
;utcd = utc0
;utcd.time = 43200000L		; 12:00
IF keyword_set(HOUR) or keyword_set(MINUTE) THEN utc1.mjd=utc1.mjd+1 $
	ELSE utc0.time = 43200000L

IF DATATYPE(missing) EQ 'UND' THEN nmssng = 0
IF DATATYPE(dt_arr) EQ 'STR' and DATATYPE(rollarr) EQ 'FLO' and keyword_set(PLOT_ONLY) THEN GOTO, plotonly
tai0=utc2tai(utc0)
tai1=utc2tai(utc1)
incr= 60l*60*24		; default increment is 1 day
IF keyword_set(HOUR) THEN incr = 60*60	; 1 hour
IF keyword_set(MINUTE) THEN incr= 60	; 1 minute

len = long((tai1-tai0)/incr) 
dt_arr = strarr(len)
rollarr= fltarr(len)
missing_arr = bytarr(len)
ind = 0l
tai = tai0
;FOR i=tai0,tai1,incr DO BEGIN
REPEAT BEGIN
	utcd = tai2utc(tai)
	dt_str = utc2str(utcd)
	pnt = get_sc_point(dt_str, SUB_DATE=sub_dt,/RETAIN)
	roll = pnt.sc_roll
	IF abs(roll) GT 360 or sub_dt NE '' or roll EQ 0 THEN missing_arr[ind]=1
	IF abs(roll) GT 360 THEN roll=0
	dt_arr(ind)=dt_str
	rollarr(ind)=roll
	ind = ind+1
	tai = tai + incr
ENDREP UNTIL ind GT len-1
;ENDFOR

missing = WHERE(missing_arr GT 0)

plotonly:

wneg=where(rollarr LT -170,nneg)
IF nneg GT 1 THEN rollarr[wneg]=rollarr[wneg]+360

nmssng=n_elements(missing)
len=n_elements(rollarr)

device, DECOMPOSED=0
window,color=10,xsiz=880,ysiz=680,/pixmap
loadct,0
;tek_color	 does not work for 24-bit color
tvlct, [getcolor('black'),getcolor('white'),getcolor('red')],0

utplot,dt_arr,rollarr,back=1,color=0,title='Roll from North for SOHO', $
	thick=1, charsize=2, ytitle='Degrees CW', yticklen=1, ygrid=1, ystyle=3, $
	xticklen=1, xgrid=1, xstyle=3, xtitle = strmid(dt_arr(0),0,4), psym=-7
IF nmssng GT 1 THEN outplot,dt_arr[missing],rollarr[missing],psym=2,color=2
xyouts,150,160,'Red indicates bad or no data',/device,color=2,size=2

IF !p.color GT 300 THEN true = 1 ELSE true=0
theplot = tvrd(true=true)

window,0,xsiz=880,ysiz=680

utplot,dt_arr,rollarr,back=1,color=0,title='Roll from North for SOHO', $
	thick=1, charsize=2, ytitle='Degrees CW', yticklen=1, ygrid=1, ystyle=3, $
	xticklen=1, xgrid=1, xstyle=3, xtitle = strmid(dt_arr(0),0,4), psym=-7
IF nmssng GT 1 THEN outplot,dt_arr[missing],rollarr[missing],psym=2,color=2
xyouts,150,160,'Red indicates bad or no data',/device,color=2,size=2

gifnm = '~/plots/'+dt0+'sc_roll.gif' 
print,'Writing ',gifnm

IF TRUE THEN BEGIN
	im2d=color_quan(theplot,1,r,g,b)
	write_gif,gifnm,im2d,r,g,b
ENDIF ELSE write_gif,gifnm,theplot

IF keyword_set(ZOOM) THEN BEGIN
    IF anytim2tai(dt_arr[len-1]) GT anytim2tai('2010/10/28') THEN BEGIN
    	yrng=[-7.9,7.9] 
	plotsym=-7
    ENDIF ELSE BEGIN
    	yrng=[-3,2]
	plotsym=0
    ENDELSE
    fineroll=rollarr
    w=where(rollarr GT 170,nw180)
    IF nw180 GT 1 THEN fineroll[w]=fineroll[w]-180
    window,1
    plotvtime,dt_arr,fineroll,strmid(dt_arr(0),0,4),title='SOHO Roll from Solar North', ytitle='Deg CW', charsi=1.5, yrange=[yrng[0],yrng[1]], /NOWIN,psym=plotsym
    IF nw180 GT 1 THEN oplotvtime,dt_arr[w],fineroll[w],' +180 deg',psym=7,color=4
    IF nmssng GT 1 THEN oplotvtime,dt_arr[missing],fineroll[missing],' MISSING',psym=7,color=2
    pngnm='~/plots/sohoroll_'+dt0+'_zoom.png'
    print,'Writing ',pngnm
    x=ftvread(/png,filename=pngnm, /noprompt)
ENDIF

end
