pro dpc_summary, outfil
;+
;NAME: 
;	dpc_summary
;PURPOSE:
;	To list the unique post-launch high word DPC values (observables)
;	and the low word DPC values (formatting)
;SAMPLE CALLING SEQUENCE:
;	dpc_summary
;	dpc_summary, 'xyz.out'
;HISTORY:
;	Written 6-Mar-96 by M.Morrison
;V1.1	11-Mar-96 (MDM) - Added showing the output size of the data product in
;			  the format summary portion
;			- Corrected the description to be correct for the
;			  format portion
;-
;
if (n_elements(outfil) eq 0) then outfil = 'dpc_summary.txt'
;
get_dpc_info, info0, /struct
dpc = info0.dpc
flight = (dpc gt 0)
ss = where(flight)
info = info0(ss)
;
dpc = info.dpc
hword = mask(dpc, 16, 16)
lword = mask(dpc,  0, 16)
;
ss_uhword = uniq(hword, sort(hword))
ss_ulword = uniq(lword, sort(lword))
;
str1 = string(hword(ss_uhword), format='(1x, z4.4, "    ")')
str2 = string(info(ss_uhword).mnem+'                       ', format='(3x, a25)')
str3 = string(info(ss_uhword).comment)
out1 = str1 + str2 + str3
prstr, out1, /nomore
;
str1 = string(lword(ss_ulword), format='(1x, 4x, z4.4)')
str2a = string(info(ss_ulword).nx, format='("(",i6,"x")')
str2b = string(info(ss_ulword).ny, format='(i4)') + ")  "
str2 = string(info(ss_ulword).mnem+'                       ', format='(3x, a25)')
str3 = string(info(ss_ulword).comment)
out2 = str1 + str2 + str2a+str2b+ str3
prstr, out2, /nomore
;
file_append, outfil, ['DPC_SUMMARY  Ver 1.1  Program Run: ' + !stime, ' ', 'Summary of observables: ', ' '], /new
file_append, outfil, out1
file_append, outfil, [' ', 'Summary of formats: ', ' ']
file_append, outfil, out2
;
end