function rd_sci5k, sttim0, entim0, qdebug=qdebug
;+
;NAME:
;	rd_sci5k
;PURPOSE:
;	To read records of SCI5K data
;SAMPLE CALLING SEQUENCE:
;	recs = rd_sci5k(sttim, entim)
;HISTORY:
;	Written 12-Sep-96 by M.Morrison
;-
;
sttim = fmt_tim(sttim0)
entim = fmt_tim(entim0)
out = 0b
for iday=gt_day(sttim),gt_day(entim) do begin
    if (iday eq gt_day(sttim)) then sttim2 = sttim else sttim2 = fmt_tim(iday)
    if (iday eq gt_day(entim)) then entim2 = entim else entim2 = gt_day(iday, /str) + ' 24:00'
    if (keyword_set(qdebug)) then print, iday, gt_day(sttim), gt_day(entim)
    if (keyword_set(qdebug)) then print, fmt_tim(sttim2), fmt_tim(entim2)
    ;
    tarr = anytim2ex(sttim2)
    fid = ex2fid(tarr)
    strec = gt_time(sttim2)/1000.  *24/15.           ;24 packets per major frame (15sec)
    enrec = gt_time(entim2)/1000.  *24/15.           ;24 packets per major frame (15sec)            
    ;
    strec = strec > 0 < 138239
    enrec = enrec > 0 < 138239
    infil = concat_dir(getenv('MDI_SCI5K_DIR'), strmid(fid, 0, 6) + '.sci')
    ;
    if (keyword_set(qdebug)) then print, 'Reading ', infil, ' records ', strec, enrec
    out0 = rd_hk(infil, strec, enrec, /new, qdebug=qdebug)
    if (data_type(out0) eq 8) then begin
	if (data_type(out) eq 8) then out = str_concat(out, out0) else out = out0
    end
end
;
return, out
end