pro plot_loi_mmad, sttim, entim, tim_c, data_c, tim_v, data_v, $
		sig=sig0, hc=hc, qstop=qstop, mark_alt=mark_alt
;+
;NAME:
;	plot_loi_mmad
;PURPOSE:
;	To plot the LOI-V and LOI-C data
;SAMPLE CALLING SEQUENCE:
;	plot_loi_mmad, sttim, entim
;	plot_loi_mmad, '2-oct','4-oct',tim_c, data_c, tim_v, data_v
;HISTORY:
;	Written Oct-96 by M.Morrison
;	16-Oct-96 (MDM) - Modified to plot the last 48 hours if no
;			  times are passed in
;	14-Oct-98 (CED) - Fixed crash condition when no LOI data were present.
;			  Updated to Version 2.0
;-
;
if (keyword_set(hc)) then begin
    set_plot, 'ps
    device, /land
end
;
if (n_elements(sttim) eq 0) then sttim = fmt_tim(anytim2ints(ut_time(), off=-48*60.*60))
if (n_elements(entim) eq 0) then entim = ut_time()
;
if (n_elements(sig0) eq 0) then sig=[3,3] else sig=sig0
if (n_elements(sig) eq 1) then sig = [sig, sig]
;
rd_loi_mmad, 'c', sttim, entim, tim_c, data_c
rd_loi_mmad, 'v', sttim, entim, tim_v, data_v
;
!p.multi = [0,1,2]

if isvalid(data_c) then begin
	temp1 = data_c 
	for i=1,2 do temp1 = temp1(avoid_spikes(temp1))
	idev1 = stdev(temp1, iavg1)
	utplot, tim_c, data_c, timerange=[sttim, entim], ytit='LOI-C', yr=[-1,1]*sig(0)*idev1+iavg1, psym=3, /xstyle
	if (keyword_set(mark_alt)) then mark_alt_times, sttim, entim
end else begin
	no_data_notice,["No LOI-C data!!","(Plot range: "+sttim+" - "+entim+")"],charsize=1.25
end

if isvalid(data_v) then begin
	temp2 = data_v 
	for i=1,2 do temp2 = temp2(avoid_spikes(temp2))
	idev2 = stdev(temp2, iavg2)
	utplot, tim_v, data_v, timerange=[sttim, entim], ytit='LOI-V', yr=[-1,1]*sig(1)*idev2+iavg2, psym=3, /xstyle
	if (keyword_set(mark_alt)) then mark_alt_times, sttim, entim
end else begin
	no_data_notice,['No LOI-V data!!',"(Plot range: "+sttim+" - "+entim+")"],charsize=1.25
end
;
;
;
plottime, 0, 0, 'PLOT_LOI_MMAD  Ver 2.0'
plottime
pprint, reset=keyword_set(hc)
if (keyword_set(qstop)) then stop
end