pro plot_loi_summary, sttim, entim, tim_c, data_c, tim_v, data_v, $
    which=which, sig=sig, clean=clean, every=every, offset=offset, quiet=quiet, $
    tune=tune, focus=focus, event=event, outfil=outfil, ps=ps, gif=gif
;+
;NAME:
;	plot_loi_summary
;PURPOSE:
;	To plot the LOI-V and LOI-C data
;SAMPLE CALLING SEQUENCE:
;	plot_loi_summary, sttim, entim
;	plot_loi_summary, '2-oct','4-oct',tim_c, data_c, tim_v, data_v
;HISTORY:
;	Written Dec-99 by R. Bush
;	Combines plot_loi_mmad and the qplot function of rd_loi_mmad
; Apr 02 - modified plot titles
;-
;
prog_ver = 'Plot_LOI_Summary  Ver 1.1'

if (n_elements(sttim) eq 0) then sttim = fmt_tim(anytim2ints(ut_time(), off=-48*60.*60))
if (n_elements(entim) eq 0) then entim = ut_time()
if (n_elements(which) eq 0) then which = 'both'

if (n_elements(sig) eq 0) then sig=[2.0,2.0] else sig=sig
if (n_elements(sig) eq 1) then sig = [sig, sig]

dev_status = !d.name

if (keyword_set(ps)) then begin
    if (n_elements(outfil) eq 0) then outfil = 'loi_summary.ps'
    set_plot, 'ps'
    device, filename= outfil, /land
    loadct, 0
end

if (keyword_set(gif)) then begin
    if (n_elements(outfil) eq 0) then outfil = 'loi_summary.gif'
    set_plot, 'z'
    tv2, 800, 600, /init
    loadct, 0
    erase
end

tuning_file = concat_dir(getenv('MDI_CAL_INFO'),'mdi_tuning.txt')
tuning = rd_tfile(tuning_file,3,1)
tune_times = reform(tuning(0,*) + ' ' + tuning(1,*))
deltav = reform(float(tuning(2,*)))

events_file = concat_dir(getenv('MDI_CAL_INFO'),'mdi_events.txt')
events = rd_tfile(events_file,3,1)
event_times = reform(events(0,*) + ' ' + events(1,*))
event_flag = reform(events(2,*))

if ((which eq 'c') or (which eq 'both')) then begin
    rd_loi_summary, 'c', sttim, entim, tim_c, data_c, clean=clean, every=every, quiet=quiet 
end

if ((which eq 'v') or (which eq 'both')) then begin
    rd_loi_summary, 'v', sttim, entim, tim_v, data_v, clean=clean, every=every, offset=offset, quiet=quiet
end

if (which eq 'both') then begin
    !p.multi = [0,1,2]
end else begin
    !p.multi = [0,1,1]
end

tr = [sttim,entim]

if ((which eq 'c') or (which eq 'both')) then begin
    if (n_elements(data_c) ne 0) then begin
        tmp_c = data_c(avoid_spikes(data_c))
        idev_c = stddev(tmp_c)
        iavg_c = mean(tmp_c)
        yr_c = [-1,1]*sig(0)*idev_c + iavg_c
        print, 'Ic mean =', iavg_c, ' Ic stdev =', idev_c, ' Ic plot range =', yr_c
        tt = 'LOI-Proxy Continuum'
        yt = 'Intensity - counts'
        utplot, tim_c, data_c, timerange=tr, yr=yr_c, title=tt, ytit=yt, psym=3, /xstyle, /ynozero
        if (keyword_set(focus)) then begin
            xx = where(events(2,*) eq 'f', n_events)
            for i=0,n_events-1 do outplot, replicate(anytim2ints(event_times(xx(i))),2), !y.crange, linestyle=1
        if (keyword_set(event)) then begin
            xx = where((event_flag eq 's') or (event_flag eq 'c'), n_events)
            for i=0,n_events-1 do outplot, replicate(anytim2ints(event_times(xx(i))),2), !y.crange
        end
        end
    end else begin
        no_data_notice,["No LOI-C data!!","(Plot range: "+sttim+" - "+entim+")"],charsize=1.25
    end
end

if ((which eq 'v') or (which eq 'both')) then begin
    if (n_elements(data_v) ne 0) then begin
        tmp_v = data_v(avoid_spikes(data_v))
        idev_v = stddev(tmp_v)
        iavg_v = mean(tmp_v)
        yr_v = [-1,1]*sig(1)*idev_v + iavg_v
        print, 'V mean =', iavg_v, ' V stdev =', idev_v, ' Ic plot range =', yr_v
        tt = 'LOI-Proxy Velocity'
        yt = 'velocity - m/s'
        utplot, tim_v, data_v, timerange=tr, yr=yr_v, title=tt, ytit=yt, psym=3, /xstyle, /ynozero
        if (keyword_set(tune)) then begin
            for i=0,n_elements(tune_times)-1 do outplot, replicate(anytim2ints(tune_times(i)),2), !y.crange, linestyle=1
        end
        if (keyword_set(event)) then begin
            xx = where((event_flag eq 's') or (event_flag eq 'v'), n_events)
            for i=0,n_events-1 do outplot, replicate(anytim2ints(event_times(xx(i))),2), !y.crange
        end
    end else begin
        no_data_notice,['No LOI-V data!!',"(Plot range: "+sttim+" - "+entim+")"],charsize=1.25
    end
end

plottime, 0, 0, prog_ver
plottime, 0.6, 0, 'Plot Made '+!stime 


if (keyword_set(ps)) then begin
    device,/close
end

if (keyword_set(gif)) then begin
    ssw_file_delete, outfil
    zbuff2file, outfil, /gif
end

set_plot, dev_status
end