pro xdisp_trace0, head, img, img2, hc=hc, $
	summary=summary, margin=margin, $
	disp_gen=disp_gen, smin=smin, smax=smax, sigma=sigma
;
;+
;NAME:
;	xdisp_trace
;PURPOSE:
;	To display single TRACE test images
;SAMPLE CALLING SEQUENCE:
;	xdisp_trace
;	xdisp_trace, head, img, img2
;	xdisp_trace, /summary, /hc
;	xdisp_trace, sig=3
;	xdisp_trace, smin=200, smax=500
;OUTPUT:
;	head	- the header array
;	img	- The 1040x1032 image
;	img2	- The 1024x1024 extracted image
;OPTIONAL KEYWORD INPUT:
;	summary	- Use "img_summary" to display the image
;	hc	- Make a hardcopy
;	sigma	- Force the display range to be +/- "N" sigma
;	smin	- Force the image scaling minimum value
;	smax	- Force the image scaling maximum value
;	disp_gen- If set, then use "disp_gen" code 1
;HISTORY:
;	Written 14-Oct-96 by M.Morrison
;	21-Oct-96 (MDM) - Added /SUMMARY, /HC, SIG and MM
;			  options
;	23-Oct-96 (MDM) - Added putting min/max/avg/dev info
;			  for the default image display
;	23-Oct-96 (MDM) - Renamed XDISP_TRACE0
;-
;
;
;
indir = ['/td01/log/rawimage', '/td02/log/rawimage']
ff = file_list(indir, '*')
ff = reverse(ff)
menu = ['*** Refresh File Listing ***', ff]
;
ii = 0
while (ii ne -1) do begin
    ii = xmenu_sel(menu, /one)
    ii = ii(0)
    if (ii eq 0) then begin
	ff = file_list(indir, '*')
	ff = reverse(ff)
	menu = ['*** Refresh File Listing ***', ff]
    end
    if (ii ge 1) then begin
	infil = ff(ii-1)
	break_file, infil, dsk_log, dir00, filnam, ext
	tit = filnam + ext
	rd_trace_i0, infil, -1, head, img
	img2 = img(9:1032, 0:1023)
	if (keyword_set(summary)) then begin
	    if (n_elements(margin) eq 0) then margin=4
	    img_summary, img2, tit, brightest=10, dimmest=10, margin=margin, hc=hc
	end else begin
	    imin = min(img2, max=imax)
	    idev = stdev(img2, iavg)
	    foot1 = 'Min/Max: ' + strtrim(imin,2) + '/' + strtrim(imax,2) + $
		  '  Avg/Dev: ' + strtrim(iavg,2) + '/' + strtrim(idev,2)
	    disp_gen, keyword_set(disp_gen), img2, '', tit, hc=hc, $
			smin=smin, smax=smax, sigma=sigma, $
			foot1=foot1
	end
	;tvscl, rebin(img(9:1032, 0:1023), 512, 512)
	if (!d.name eq 'X') then wshow
    end
end
;
end