pro trace_request_summary, finished, url, outfiles=outfiles, nimg=nimg
;+
;   Name: trace_request_summary
;
;   Purpose:
;      provide html summary of a completed TRACE data request job 
;
;   History:
;      25-May-1998 - S.L.Freeland - TRACE WWW request interface
;      27-May-1998 - S.L.Freeland - add version/extension to link text  
;-

debug=keyword_set(debug)
configure_http,/trace                     ; set WWW defaults to TRACE

if not data_chk(/scalar,/string,finished) then begin
  box_message,'Problem with input
  return
endif

if not file_exist(finished) then begin
  box_message,'No file: ' + finished
  return
endif  

break_file,finished,ll,pp,jobname,vv,ee

contents=rd_tfile(finished)
histss=where(strpos(contents,';') ne -1, hcnt)
if hcnt eq 0 then begin
    box_message,'Problem with ' + finished
    return
endif    
history=contents(histss)
chistory=strtrim(str_replace(history,';',''),2)
sscat=0
ssorder=(where(strpos(chistory,'trace_order_data') ne -1))(0)
ssreq=(where(strpos(chistory,'trace_do_data_requests') ne -1))(0)

; ----------  derive HTML output document ---------------------
htmlfile=str_replace(finished,'success','html')
html_doc,htmlfile,/header
file_append,html,'<h1>TRACE Data Request Summary for Job: ' + jobname + '</h1>

items=strsplit(chistory,':',tail=values)

for i=0,n_elements(chistory)-1 do begin
   pre=''
   case i of
       sscat:pre='<dl>User TRACE Catalog Search 
       ssorder: pre='</dl><dl> Users Data Request FORM
       ssreq:pre='</dl><dl> Offline Job Procsssing
       else:
   endcase
  if pre ne '' then file_append,htmlfile,pre
  file_append, htmlfile, '<dd><b><em>' + items(i)+ $               ; update WWW
     '</b></em>&#32 <font color=red>' +  values(i) +'</font>
endfor
file_append,htmlfile,'</dl>'

nfiles=n_elements(outfiles)

; ---------- if outfiles list passed, include some statistics
if nfiles gt 0 then begin
   file_append,htmlfile,'<h4>Output File Statistics </h4>
   break_file,outfiles,ll,pp,ff,ee,vv
   fsizes=file_size(outfiles,/string,/auto)
   flink=strmids(outfiles,strpos(outfiles,'/TRACE'),150)
   flinks='<a href="'+flink+'">'+ff+ee+vv+'</a>'
   ff=['File Name',flinks]
   fsizes=['Size',fsizes]
   ftable=[[ff],[fsizes]]
   nimgs=intarr(nfiles)
   flat=where(strpos(chistory,'flat') ne -1,fcnt)
   flat=fcnt gt 0
   if keyword_set(nimg) then begin
      if flat then nimgs(*)=1 else begin
         for i=0,nfiles-1 do begin 
            read_trace,outfiles(i),-1,ind,taglist='date_obs'           
            nimgs(i)=n_elements(ind)
         endfor       
      endelse
      ftable=[[ff],[fsizes],['#Images',strtrim(nimgs,2)]]
   endif     
   file_append,htmlfile,strtab2html(transpose(ftable),/row0)
endif

html_doc,htmlfile,/trailer
; ----------------------------------------------------------------
url=http_names(htmlfile)


if debug then stop

return
end