function gbo_paths, gbo_only=gbo_only, noshell=noshell
;
;+
;NAME:
;	gbo_paths
;PURPOSE:
;	To return the directory list of where ground based data resides
;CALLING SEQUENCE:
;	dirs = gbo_paths()
;OPTIONAL KEYWORD INPUT:
;	gbo_only - If set, only pass back the "standard" gbo directories,
;		   do not pass back things like "DIR_GEN_SYOPTIC"
;       noshell - if set, avoid shell (from data-paths2) messages
;OUTPUT:
;	returns a string array of the environment variables where
;	DIR_GBO is defined
;RESTRICTIONS:
;	Currently only works for workstations
;HISTORY:
;	Written 26-Jun-92 by M.Morrison
;	11-Sep-92 (MDM) - Added DIR_GEN_SYNOPTIC to the derived list
;	21-Jan-93 (MDM) - Modified to use DATA_PATHS2 routine
;	27-Jan-93 (MDM) - Added /GBO_ONLY option
;       12-Apr-94 (SLF) - Add NOSHELL keyword/function; eliminate old garbage
;-
;
case 1 of 
   keyword_set(noshell): begin
      topgbo=get_logenv('gdb')
      if topgbo eq '' then begin
         message,/info,'$gdb not defined'
         out=''
      endif else begin
         out=findfile(topgbo)
         chkdir=wc_where(out,'gbo9*',gbocnt)
         if gbocnt eq 0 then out='' else out=concat_dir(topgbo,out(chkdir))
      endelse
   endcase
   else:  out = data_paths2(/filter, /gbo, /noreformat)
endcase

if (not keyword_set(gbo_only)) then out = [out, '$DIR_GEN_SYNOPTIC']
;
return, out
end