#!/bin/csh
#
#    offline
#    remove files from remote directories
#    
#    Calling Sequence:
#       offline file [/showpix /ucon /gen /sxt /bcs /hxt /wbs]
#
#    History:
#       1-Feb-1994
#
set relenv=ys
set file=()
set exten=".pro"
set extension="1"

foreach argx ($argv)
   switch ($argx)
      case /showpix:
      case /pix:
         set relenv=DIR_GEN_SHOWPIX
         set exten=".genx"
         set fpath=""
         breaksw
      case /gen:
         set fpath=atest/soft/gen
         breaksw
      case /sxt:
         set fpath=atest/soft/sxt
         breaksw
      case /bcs:
         set fpath=atest/soft/bcs
         breaksw
      case /hxt:
         set fpath=atest/soft/hxt
         breaksw	 
      case /wbs:
         set fpath=atest/soft/wbs
         breaksw
      case /ucon:
          set fpath=ucon/soft/$user
          breaksw
      case /noext:
      case /noextension:
         set extension="0"
         breaksw
      default:
         set file=($file $argx)
         breaksw
      endsw
end

if (($#file == "0") || (!($?fpath))) then 
	 echo You must specify a both a filename and a relative pathname
         echo "(defined relative pathnames use one of the switches below)"
         echo " "
         echo Calling Sequence:
         echo "   offline file [/showpix /ucon /gen /sxt /bcs /hxt /wbs]"
         exit
endif

if (!($?online_hosts)) then
   set online_hosts=(isass0.solar.isas.ac.jp sxt.space.lockheed.com)
   set online_hosts=($online_hosts sxt4.oscs.montana.edu)
endif

if ($relenv == "DIR_GEN_SHOWPIX") then
   if ($file:h == $file:t) then
      echo show_pix update and no subdirectory specified
      echo Defaulting to genpix/misc subdirectory
      set fpath=misc
   endif
endif

if ($extension == "1") then
   set test_ext=`echo $file | grep $exten`
   if ($test_ext == "") then
      set file=$file$exten
   endif
endif

foreach host ($online_hosts)
   set remenv=`rsh $host "setenv ys_quiet; source .yslogin; printenv $relenv"`
   set cmd="rsh $host /bin/rm -f $remenv/$fpath/$file"
   echo $cmd
   $cmd
end
exit