function weekfiles, start, stop, $
	obs=obs, pnt=pnt, xbd=xbd, xad=xad, fem=fem, $
	highver=highver
;
;+
;   Name: weekfiles
;
;   Purpose: return file names of weekly data base files
;
;   Input Parameters (Optional):
;      start - start time of interest (default = earliest)
;      stop  - stop time of interest (default = latest)
;
;   Keyword Parameters:
;      obs, pnt, xbd, xad, fem - prefix for desired weekly file
;				 assume one and only one set
;
;   Disclaimer - since I tried to make use of alot of existing routines,
;		 some loss of efficiency is encountered - if you want
;		 speed, rewrite it and let me know where it is. 
;
;   History - slf, 24-feb-1992
;
;-
;
; use weekid.pro to return files for selected prefix
weekfils=weekid(obs=obs,fem=fem,xbd=xbd,xad=xad,pnt=pnt,/all)
;
split_files,weekfils,weekpath,files		; split path/filename
underpos=strpos(files(0),'_')			; locate rootid center
rootid=strmid(files,underpos-2,5)		; extract yy_ww
;
if keyword_set(highver) then begin		; only 1/week
   uniqweek=uniq(rootid)			; already sorted(?**)
   weekfils=weekfils(uniqweek) 			; reduced filelist
   rootid=rootid(uniqweek)			; and rootid list
endif 
;
case n_params() of				; start/stop optional
   0: begin					; neither one
         firstnam=rootid(0) 
         lastnam=rootid(n_elements(rootid)-1)
      endcase
   1: begin					; one (start=stop)
         firstnam=tim2weekid(start) 
	 lastnam=firstnam
      endcase
   2: begin					; both (range)
	 firstnam=tim2weekid(start) 
	 lastnam=tim2weekid(stop) 
      endcase
endcase
;
range=where(rootid ge firstnam and rootid le lastnam,count)
;
if count eq 0 then retval='' else retval=weekfils(range)
;
return,retval
end