pro mo_init, drive, override=override , old=old
;
;+
;   Name: mo_init
;
;   Purpose: initialize one or more mo disks
;
;   Input Parameters:
;      drive - optional drive number (default is drive 0)
;
;   Keyword Parameters:
;      override - if set, override check for user (root) and host
;
;	old	- passes flag to mo_prep
;		  used for formatting old (1Gb MOs)
;		  if /old flag is not present, will default to higher density
;
;   Calling Sequence:
;      [Log in as root on one of the hosts in defined hosts list]
;      mo_init [,drive] [,/old]
;
;   History:
;      4-Feb-1994 (SLF)
;        26-June-95 (GAL), added 18 and 15
;	  3-Oct-95 (LS), added all flare MO machines in motab
;	 18-Oct-95 (LS), added /old option.  see mo_prep
;-
;
hosts=['flare2','flare6','flare13','flare14','flare15','flare16','flare18','flare20','flare21','flare22','flare23','flare24']
host=get_host()
chkhost=where(host eq hosts,cnt)

; only root
if not keyword_set(override) then begin
   if  getenv('HOME') ne '/' then begin
         tbeep,3
      message,/info,'Must be root to initialize MOS, exiting...
      return
   endif 

   if cnt eq 0 then begin
      tbeep
      message,/info,'MO initialize on runs on the following hosts '
      more,hosts
      return
   endif
endif

if n_elements(drive) eq 0 then drive=0
driven=strtrim(drive,2)
volume='/mo/' + host + '.' + driven 

resp=''
print,'Load a write-enabled disk'
read,'Hit <RET> when ready or "q" to quit program: ',resp
while strlowcase(strmid(resp,0,1)) ne 'q' do begin
    message,/info,'Calling: mo_prep,/init,' + host + ',' + driven
    mo_prep,host,drive,/init,old=old
    tbeep
    message,/info,'Initialization completed, ejecting disk'
   spawn,'smoeject ' + driven
   print,'Load next disk and hit <RET> to initialize'
   read,'Enter "q" to quit program: ',resp
endwhile

return
end