function op_term_sum,event2,og_table,num
;+
; NAME:
;   op_term_sum
; PURPOSE:
;   Called by op_first_guess routines to find the times of
;   the programmed terminator images.  Returns an information string
; CALLING SEQUENCE:
;   Text_string = op_term_sum(event2,num)
; INPUTS:
;   event2 	= The op_edit event data structure
; OPTIONAL OUTPUTS:
;   num		= The number of terminator images.
; MODIFICATION HISTORY:
;  14-oct-93, J. R. Lemen (LPARL), Written
;-

op_cmd = 63					; Find all ctl AUT
ij = where(event2.og eq og_table(op_cmd).og,num)
if num eq 0 then return,'No SXT Term. Images'

Text = strarr(num)				; Set up output variable
count = -1 & qflag = 0
for i=0,n_elements(event2)-1 do begin
  if event2(i).og eq og_table(op_cmd).og then begin
     count = count+1 
     qflag = 1
  endif else 					$
  if ((event2(i).og eq og_table(8).og)   or	$  ; KSC AOS-A-DAY
      (event2(i).og eq og_table(9).og)   or	$  ; KSC AOS-B-DAY
      (event2(i).og eq og_table(10).og)  or	$  ; KSC AOS-A-NT
      (event2(i).og eq og_table(11).og)  or	$  ; KSC AOS-B-NT
      (event2(i).og eq og_table(17).og)  or	$  ; DSN AOS-A
      (event2(i).og eq og_table(18).og)) and 	$  ; DSN AOS-B
       (count ge 0) and qflag then 		$
  begin

      Text(count) = 'Terminator: '+fmt_tim(event2(ij(count)).timarr)+	$
		'     Downlink: '+fmt_tim(event2(i).timarr)+'  '+  	$
		event2(i).station
      qflag = 0
  endif
endfor

return,Text
end