function gt_tfss, item, iaxis, mask=mask
;
;+
;NAME:
;	gt_tfss
;PURPOSE:
;	To extract the word corresponding to the TFSS data value
;	Default output is in arcseconds.
;CALLING SEQUENCE:
;	x = gt_tfss(pnt_data, 0)
;	y = gt_tfss(pnt_data, 1)
;	tfss = gt_tfss(ada_data)
;METHOD:
;	The input can be a structure or a scalar.  The structure can 
;	be the ADA data record or the PNT record.  If the input is the ADA file,
;	then only the first TFSS value recorded in the major frame is
;	returned.
;INPUT:
;	item	- A structure or scalar.  It can be an array.  
;OPTIONAL INPUT:
;	iaxis	- Axis to extract (0=x, 1=y)
;		  If not passed, the output is 2xN where N is the number
;		  of datasets passed in.
;	mask	- If set, force the bit mask to be performed (older PNT data
;		  sets were saved incorrectly)
;OUTPUT:
;	returns	- The TFSS position in arcsec
;HISTORY:
;	Written 21-Apr-92 by M.Morrison
;	 6-May-92 (MDM) - Added "mask" keyword option
;-
;
siz = size(item)
typ = siz( siz(0)+1 )
if (typ eq 8) then begin
    out = item.tfss(*,0)
    ii = tag_index(item, 'TIME')
    if (ii ne -1) then begin		;PNT data was passed
	;no mask is required - older PNT datasets need mask ?
    end else begin
	out =  mask(out, 4, 12)
    end
    if (keyword_set(mask)) then out =  mask(out, 4, 12)
    out = unsign(out, 12)*.00054*60*60	;convert to degrees
end else begin
    out = item*.00054*60*60
end
;
if (n_elements(iaxis) ne 0) then begin
    if ((iaxis ge 0) and (iaxis le 1)) then begin
        out = out(iaxis, *)
    end else begin
        message, 'The "iaxis" value must be between 0 and 1', /info
        message, 'Returning all limbs', /info
    end
end
;
return, out
end