function get_info, index, noninteractive=noninteractive, longform=longform, $
		itemnumber=itemnumber
;
;+
;   Name: get_info
;
;   Purpose: decode Yohkoh index or roadmap information into string info_array
;
;   Input Paramters:
;      index - Yohkoh index or roadmap (scaler or vector)
;
;   Optional Input Keywords:
;       noninteractive  = If set, does not prompt user, but only returns
;                         the array.  If infil is specified, the summary
;                         is written to an output file.
;       longform        = If set, also put out the percentage of the image
;                         which is available, and the heliocentric coord.
;       itemnumber      = If set, will compute the relative item number
;                         from this starting value.  If a vector is passed,
;
;   Restrictions:
;      just time and DP mode for non-SXT index input currently
;
;   Method:
;      driver (allow more intuitive get_info call to replace get_info2 call)
;      for sda, just calls get_info2
;
;   History: (SLF) 18-May-1993 (people were calling get_info, not get_info2)
;	16-Oct-93 (MDM) - Modified to recognized non-SXT roadmaps
;	 9-Dec-93 (MDM) - Added /LONGFORM option (to be passed to GET_INFO2)
;	 9-Sep-94 (GAL) - Added itemnumber option (passed to get_info2) and
;			  documented all the optional inputs.
;-
;
retval=''
;
;input must be structure

uniqt_index=['BCS','HXT','SXT','WBS']		; uniq tag names
;uniqt_road =['xxx','xxx','SHAPE_CMD','xxx']
uniqt_road =['TOTAL_CNTS','SUM_L','SHAPE_CMD','SXS1']	;MDM added 16-Oct-93

if str_is(index) then begin
   tagnames=strupcase(tag_names(index))
   if str_is(index.(0)) then which=where(tagnames(1) eq uniqt_index,cnt) else $
      which=where_arr(uniqt_road,tagnames,cnt)
   if cnt gt 0 then begin
      case uniqt_index(which(0)) of
         'SXT': retval=get_info2(index,noninteractive=noninteractive, $
			         longform=longform,itemnumber=itemnumber)
;        'BCS':
;        'HXT':
;        'WBS':
;        Add other instrument routines here when available
;        For now, can do time field and dp fields
	 else: begin
            message,/info,"Can only do time, dp-rate and mode for: " + $
		uniqt_index(which(0))
            retval= $
		fmt_tim(index) 	+ '   ' 			+ $
		gt_dp_mode(index,/string,/short) + '/' 	+ $
		gt_dp_rate(index,/string,/short)
         endcase
      endcase

   endif else message,/info,"Don't recognize this structure"      

endif else message,/info,'Input must be roadmap or index structure...'

return,retval
end