pro ttim2ex, rec1, daytim, year0
;
;+
;NAME:
;	ttim2ex
;PURPOSE:
;	Convert from the telemetry time block to the external representation
;INPUT:
;	rec1	- raw telemetry block (bytarr(144,64))
;OUTPUT:
;	daytim	- 7-element array time vector 
;OPTIONAL INPUT:
;	year0	- the year (since the telemetry does not have the year in it!)
;HISTORY:
;	Written Fall '91 by M.Morrison
;	 6-Jan-92 (SLF) - empirically derived mask for temparr(0) 
;			  since 1992 data led to DOY = (1600 + temparr(1) stuff) 
;	 8-Mar-92 (MDM) - Changed S/W to derive year from the "leap year nibble"
;			  Assume that year is 1991 + "leap year nibble"
;			  Need to have ISAS redefine that nibble so there is
;			  no problem next year.
;-
;
	common ttim2ex_blk, year	;Since the telemetry does not have 
					;the year, it must be set by hand.  
					;It is set once and saved for future calls
;
	daytim = intarr(7)
	temparr = rec1(0:6, 0)
;
	if (n_elements(year0) eq 0) then begin		;no year passed in by hand
	    year = 91 + temparr(0)/16
	end else begin
	    year = year0
	end

	;doy   =  temparr(0)*100     + (temparr(1)/16)*10 + (temparr(1) and 15)
	doy    =  (temparr(0) and 15)*100     + (temparr(1)/16)*10 + (temparr(1) and 15)
	hour   = (temparr(2)/16)*10  + (temparr(2) and 15)
	minute = (temparr(3)/16)*10  + (temparr(3) and 15)
	second = (temparr(4)/16)*10  + (temparr(4) and 15)
	msec   = (temparr(5)/16)*100 + (temparr(5) and 15)*10 + (temparr(6)/16) 

	doy2date, doy, year, month, date

	daytim(0) = hour
	daytim(1) = minute
	daytim(2) = second
	daytim(3) = msec
	daytim(4) = date
	daytim(5) = month
	daytim(6) = year

	end