pro fastdoc, module, summ=summ, multi=multi, outarr=outarr, noprint=noprint
;
;+
;   Name: fastdoc 
;
;   Purpose: user front end to faster idl documentation extraction/display
;   
;   Input Parameters: 
;      module - string name (or substring) of module to locate 
;
;   Optional Keyword Parameters:
;       summ  - if set, just display procedure/function definition
;	multi - if set, multiple versions are displayed
;
;   Calling Sequence:
;      fastdoc, module [,/summ, /multi]
;
;   History: slf, 9-Aug-1992
;	     slf, 8-feb-1993 - use rd_tfile (via doc_head)
;            slf, 15-mar-1993 - minor cleanup , quieter
;	     slf, 10-Jan-1994 - call oneliner if no module
;	     slf, 25-Jan-1994 - add outarr, loop
;-
;
qtemp=!quiet
!quiet=1					; careful if crash!!
if n_elements(module) eq 0 then oneline,/manage else begin
		  				; spawn widget
   mods=path_sw(module, multi=multi)
   summary=keyword_set(summ)
   resp=''
   for i=0,n_elements(mods)-1 do begin
      if mods(i) ne '' then begin
         resp=[resp,'-------- ' + mods(i) + ' --------']
         doc_head,mods(i),header,definition
         if summary then begin
            resp=[resp,definition]
         endif else begin
            resp=[resp,header]
         endelse
         resp=[resp,'']
      endif else resp=[resp,'-------- ' + module(i) + ' NOT FOUND --------']
   endfor 
   resp=resp(1:*)
   if not keyword_set(noprint) then more,resp
   outarr=resp
endelse
!quiet=qtemp
return
end