pro mk_time_title,index,numx,numy,ss=ss,		$
	xoff=xoff,yoff=yoff,xsize=xsize,ysize=ysize,	$
	charsize=charsize,font=font,align=align, 	$
	charthick=charthick, color=color
;+
; NAME:
;   mk_title
; PURPOSE:
;   Put Time titles on a multi-panel image plot using Yohkoh 
;   data structures
; CALLING SEQUENCE:
;   mk_time_title,index
;   mk_time_title,index,xsize=xsize,ysize=ysize
;   mk_time_title,index,numx,numy,ss=ss,xoff=xoff,yoff=yoff
; INPUTS:
;   index	- Yohkoh roadmap or index
; OPTIONAL INPUTS:
;   numx,numy   - Number of panels in the x and y directions
; OPTIONAL INPUT KEYWORDS:
;   ss	        - Subscript array
;   xoff,yoff   - X offset and Y offset in device coordinates
;   xsize,ysize - Size of each panels in device coordinates
;   align	- For call to xyouts (def = 0.5)
;   charsize    - Character size
;   charthick   - Character thickness 
;   font	- To specify Hershey character font style 
;   color	- Color of title
; RESTRICTIONS:
;   Only works for X device
; MODIFICATION HISTORY:
;  12-jul-94, Louise Harra Murnion MSSL, Written.
;-


if n_elements(ss) eq 0 then ss = indgen(n_elements(index))
npts = n_elements(ss)
if n_elements(numx) eq 0 then numx = fix(sqrt(npts))
if n_elements(numy) eq 0 then numy = fix(npts / numx)
if n_elements(xsize) eq 0 then xsize = !d.x_size / numx
if n_elements(ysize) eq 0 then ysize = !d.y_size / numy
if n_elements(xoff) eq 0 then xoff = xsize/2.
if n_elements(yoff) eq 0 then yoff = 10.
if n_elements(charsize) eq 0 then charsize = 1.
if n_elements(font) eq 0 then ffont = '' else ffont = '!'+strtrim(font,2)
if n_elements(align) eq 0 then align = .5
if n_elements(color) eq 0 then color = !p.color

for i=0,npts-1 do begin
   xx = xoff + i * xsize mod (numx*xsize) 
   yy = yoff - (i / fix(numx)) * ysize + (fix(numy)-1)*ysize
   xyouts,/dev,xx,yy,ffont+gt_time(index(ss(i)),/str),chars=charsize,align=.5
endfor
end