function time_vec, time, day, rate, nrep_mf
;
;+
;NAME:
;	time_vec
;PURPOSE:
;	Given a time vector (in the form of "days since
;	1979" and "millisec of day" and a rate, and a
;	number of repeats within a major frame, return
;	a single time vector (in units of minutes from
;	the first time)
;	
;	It is used to plot parameters where there is
;	more than value in a major frame (since there
;	is only one time returned for each major frame)
;INPUT:
;	time	- millisec of day
;	day	- days since 1979
;	rate	- DP telemetry rate
;	nrep_mf	- Number of repeats for this entry
;		  per major frame
;OUTPUT:
;	Returns	- Number of minuts since first entry
;-
;
if (n_elements(nrep_mf) eq 0) then nrep_mf = 1
;
ms_day = 86400000            ; 1 day = 86400000 msec
;
tim   = (day-day(0))*ms_day + (time-time(0))
tim   = tim/1000./60.	;convert to minutes
;
tim_rate = dprate2sec(rate)/60.	;convert to minutes
;
n = n_elements(day)
;
if (nrep_mf ne 1) then begin
    tim2 = fltarr(n,nrep_mf)
    for i=0,nrep_mf-1 do begin
	tim2(0,i) = tim + tim_rate/nrep_mf*i
    end
    tim = transpose(tim2)
end
;
return, tim
end