pro tim2pass, min2pass, warnmin=warnmin , nobeep=nobeep, quiet=quiet
;+
;   Name: tim2pass
;
;   Purpose: indicate time 2 next visible KSC contact
;
;   Calling Sequence:
;      tim2pass [,warnmin=warnmin]
;
;   History:
;      6-apr-1995 (SLF)
;      9-apr-1995 (slf) make sure jst visibles are used
;     11-may-1995 (SLF) call JST.pro (so this works anywhere)
;
;   Restrictions: for now, assumes that you are in Japan...
;-

if not keyword_set(warnmin) then warnmin=30.

qtemp=!quiet
!quiet=1

now=jst()

get_visible,anytim2weekid(now),jst0, jst1, pass, visss=vs, numss=ns,/jst
beeps=0
mess='TIM2PASS: Yohkoh Pass Status '

if vs(0) ne -1 then begin
   secs=int2secarr(jst0(vs),now)
   next=where(secs ge 0,ncnt)
   last=where(secs lt 0,lcnt)
   if lcnt gt 0 then begin
      if abs(secs(last(lcnt-1))) le 720 then begin
         beeps=beeps+1
         mess=[mess,'','**** PASS NOW IN PROGRESS ****','']
       endif
   endif 
   if ncnt eq 0 then mess=[mess,'','.. Please Enjoy Yohkoh Holiday ..']  else begin
      min2pass=round(secs(next(0))/60)
      soon = min2pass le warnmin
      delim=(['','******************************'])(soon)
      beeps=beeps + soon
      mess=[mess,delim,'Next Pass Occurs in ' + $
               strtrim(min2pass,2) + ' minutes',delim] 
   endelse      
endif else mess=['','No one has run <mk_Visible> for this week', $
                 '','Please notify SXT Chief Observer','']  


if 1-keyword_set(quiet) then prstr,strjustify(mess,/box,/center)

if beeps(0) gt 0 and 1-keyword_set(nobeep) then tbeep,beeps

!quiet=qtemp

return
end