function gt_entry, item, pfi_ffi, header=header, string=string, short=short, spaces=spaces
;
;+
;NAME:
;	gt_entry
;PURPOSE:
;	To extract the word corresponding to the SXT entry table and optionally
;	return a string variable for that item.
;CALLING SEQUENCE:
;	x = gt_entry(roadmap)
;	x = gt_entry(index)
;	x = gt_entry(index.sxt, /space)	;put single space before string
;	x = gt_entry(index, space=3)	;put 3 spaces
;METHOD:
;	The input can be a structure or a scalar.  The structure can
;	be the index, or roadmap, or observing log.
;INPUT:
;	item	- A structure or scalar.  It can be an array.  
;OPTIONAL INPUT:
;	pfi_ffi	- If "item" is not a structure then the "pfi_ffi"
;                 needs to be passed in to the routine.
;	string	- If present, return the string mnemonic (long notation)
;	short	- If present, return the short string mnemonic 
;	spaces	- If present, place that many spaces before the output
;		  string.
;OUTPUT:
;	returns	- The observing region, a integer value or a string
;		  value depending on the switches used.  It is a vector
;		  if the input is a vector
;OPTIONAL OUTPUT:
;       header  - A string that describes the item that was selected
;                 to be used in listing headers.
;HISTORY:
;	Written 13-Nov-91 by M.Morrison
;-
;
header_array = 'E'
header_array = [header_array, header_array]	;no short option at this time
fmt = "(i1)"		;8 characters
;
siz = size(item)
typ = siz( siz(0)+1 )
if (typ eq 8) then begin
    ;Check to see if an index was passed (which has the "periph" tag
    ;nested under "sxt", or a roadmap or observing log entry was
    ;passed
    tags = tag_names(item)
    if (tags(0) eq 'GEN') then out = item.sxt.obsregion $
			else out = item.obsregion
    pfi_ffi = gt_pfi_ffi(item)
end else begin
    out = item
    if (n_elements(pfi_ffi) eq 0) then begin
	print, 'GT_ENTRY: Guessing that it is PFI'
	pfi_ffi = 0	;guess
    end
end
;
if (pfi_ffi(0) mod 2) then out = mask(out, 6, 2) $	;FFI	- assumes that PFI and FFI are not mixed together!!
		else out = mask(out, 4, 2)		;PFI
;
out = gt_conv2str(out, conv2str, conv2short, header_array, header=header, $
	string=string, short=short, spaces=spaces, fmt=fmt)
;
return, out
end