function gtab_exp, itab0, fid=fid, itab=itab
;
;+
;NAME:
;       gtab_exp
;PURPOSE:
;       Extract the sequence table information for the default exposure table.
;CALLING SEQUENCE:
;       print, gtab_exp(150)
;       print, gtab_exp(roadmap(0))
;INPUT:
;       itab0   - Table number to display
;                       (or)
;                 A structure which has the sequence table and entry table
;                 that is used for a particular image.  The index and roadmap
;                 can be used.
;OPTONAL INPUT:
;       fid  - The user can specify a specific table by passing the fileid
;OUTPUT:
;       returns - A string array with the information on what parameters were
;                 used in the SXT sequence table.
;OPTONAL OUTPUT:
;       itab    - The table serial number selected
;HISTORY:
;       Written Nov-91 by M.Morrison
;	21-Nov-91 (MDM) - Added "fid" and "itab" options
;	 7-Jul-92 (MDM) - Added printing out comment lines of table load
;-
;
infil = gtab_file(itab0, ientry0, table=table, itab=itab, fid=fid, headline=headline)
table = fix(table)	;convert to integer so that "string" work properly
;
if (infil eq '') then begin
    print, 'EXITING GTAB_EXP:
    return, ' '
end
;
out = strarr(10)
off = 43*64 + 48
;
out(0) = '****** Table # ' + strtrim(itab,2) + ' (File: ' + infil + ')'
out(1) = '-------------------------------- EXPDT Tables --------------------------------'
out(2) = '                                                                              '

barr = extract(table, off, 8)
out(3) = '     Filter B/A       DPE'
for i = 0, 5 do begin
    out(4+i) = string(i, barr(i), format="(9x, i1,'/X', 11x, i2)")
end
out = [headline, out(1:*)]
;
for i=0,n_elements(out)-1 do begin
    out(i) = strmid(out(i) + '                                                      ', 0, 78)
end
return, out
end