pro sxt_ssc2file, time0, time1, outdir=outdir, $
    tiff=tiff, gif=gif, fits=fits, sscfiles=sscfiles, $
    eightbit=eightbit, sixteenbit=sixteenbit, _extra=_extra
;
;+
;   Name: sxt_ssc2file
;
;   Purpose: convert SXT ssc images -> FITS w/cleanup + registration
;
;   Input Paramters:
;      time0, time1 - time range of interest (assumes SSCFILES not passed in)
;      
;   Keyword Paramters
;      sscfiles - list of files to convert (instead of time range)
;      eightbit/sixteenbit - passed to sxt_ssc_rationalize
;      _extra - passed to sxt_ssc_rationalize 
;      
;   History:
;      Circa 1-Jan-2000 - S.L.Freeland - sscs->pretty FITS (non-quantitative)
;
;   Calls:
;      pipeline like:
;         [timerange] -> ssclist -> sxt_ssc_rationalize -> mwritefits
;         [Optional ] -> list    -> register/normalize  -> store as FITS
;                                                          w/SSW tags
;- 

fits=keyword_set(fits)
tiff=keyword_set(tiff)
gif=keyword_set(gif)


notype=total([fits,tiff,gif]) eq 0
if not data_chk(outdir,/string) then outdir=curdir()

if notype then begin 
   ftypes=str2arr('fits,tiff,gif')
   for i=0,n_elements(ftypes)-1 do begin 
      exes=execute(ftypes(i)+'=strpos(outdir,"'+ftypes(i)+'") ne -1')
      help,fits,tiff,gif
   endfor
endif

case 1 of 
   data_chk(sscfiles,/string): sscs=sscfiles
   n_params() gt 0: sscs=ssc_files(time0,time1)
   else: begin
      box_message,'Must supply times for file list via SSCFILES keyword'
      return
   endcase
endcase

nsscs=n_elements(sscs)
 
for i=0,nsscs-1 do begin 
   box_message,'Processing>> ' + sscs(i)
   rd_xda,sscs(i),-1,index,data
   sxt_ssc_rationalize,index,data,oindex,odata, $
      eightbit=eightbit, sixteenbit=sixteenbit, _extra=_extra
   prefix='ssc_'+strtrim(gt_filtb(oindex,/string,/short),2) + '_' + $
           strtrim(gt_shape_cmd(index,/x,/string),2) + '_' + $
           strtrim(data_chk(odata,/nx),2)+ '_'

   case 1 of 
      fits: begin 
         mwritefits, struct2ssw(oindex), odata, prefix=prefix, outdir=outdir 

      endcase
      else: begin 
         box_message,'fits only for this minute'
         return
      endcase
   endcase

endfor

end