function fov2nar, struct
;
;HISTORY:
;	Written Jan-93 by M.Morrison
;	19-Aug-93 (MDM) - Removed call to GT_FOV_CENTER
;	 1-Oct-93 (MDM) - Modified to handle case where there is
;			  no NAR data for the time period
;	19-Oct-93 (MDM) - Removed the call to HEL2PIX
;
;
n = n_elements(struct)
img = gt_center(struct, /angle, /cmd)/60.		;in arcminutes
i_ew = reform(img(0,*))
i_ns = reform(img(1,*))
;
sttim = anytim2ints(struct(0))
sttim.time = 0			;make sure to have a 00:00 time
entim = struct(n-1)
rd_nar, sttim, entim, nar
out = ''
if (get_nbytes(nar) gt 10) then begin
    nnar = n_elements(nar)
    temp = conv_h2p(nar.location, struct(0), suncenter=[0,0])
    ar_ew = reform(temp(0,*))*2.46/60	;turn into arcminutes
    ar_ns = reform(temp(1,*))*2.46/60
    ;
    shape = gt_shape_cmd(struct)
    pix_size = 2.^gt_res(struct) * 2.46/60	;in arcminutes
    fov_siz = reform(shape(0,*)) * pix_size
    error = fov_siz/2
    out = strarr(n)
    for inar=0,nnar-1 do begin
	r = sqrt( (i_ew-ar_ew(inar))^2 + (i_ns-ar_ns(inar))^2 )
        ;print, ar_ew(inar), ar_ns(inar), i_ew(0), i_ns(0), r
	ss = where(r-error le 0)
	if (ss(0) ne -1) then out(ss) = out(ss) + string(nar(inar).noaa, format='(i5)')
    end
end
;
return, out
end