function get_dc_rate, input1, hr=hr, qr=qr
;
;+
;NAME:
;	get_dc_rate
;PURPOSE:
;	For a given time(s) return the dark current rate in full res DN/sec
;CALLING SEQUENCE:
;	dc_rate = get_dc_rate(roadmap(0))
;	dc_rate = get_dc_rate('1-jan-92', /hr)
;INPUT:
;	input1	- The time(s) in any of the 3 standard formats
;OPTIONAL KEYWORD INPUT:
;	hr	- If set, return in HR DN/Sec
;	qr	- If set, return in QR DN/Sec
;OUTPUT:
;	Returns dark current rate in full resolution DN per second
;HISTORY:
;	Written 14-Oct-92 by M.Morrison
;-
;
coeff0 = 0.0742		;FR DN/Sec	- Uses PLOT_SDL output (plot made 13-Jul-92)
			;		- HR plot has intercept of 0.3073 HR DN/sec (=0.0768 FR DN/sec)
			;		- QR plot has intercept of 1.148  QR DN/sec (=0.0717 FR DN/sec)
coeff1 = 0.0003653	;FR DN/sec/Day	- Uses PLOT_SDL output (plot made 13-Jul-92)
			;		- HR plot has slope of 0.001517 HR DN/sec/day (=0.000379250 FR DN/sec/day)
			;		- QR plot has slope of 0.005620 QR DN/sec/day (=0.000351250 FR DN/sec/day)
ref_time = '15-sep-91'
;
tim = int2secarr(input1, ref_time)/86400	;days since reference time
out = tim*coeff1 + coeff0
;
if (keyword_set(hr)) then out = out*4
if (keyword_set(qr)) then out = out*16
;
return, out
end